topic ODS Powerpoint question in SAS Procedures

ODS Powerpoint question

bustergomez — Sat, 09 Aug 2014 19:15:49 GMT

I understand that ODS POWERPOINT is very new and has some limitations until the next version comes out.

I've been scrapping the web looking for answers however there's not much to find, a formal document or two.

My question is on every power point slide is there a way to select a different style background:

proc template;

define style styles.afgsc_title;

parent=styles.powerpointlight;

class body /

backgroundimage="afgsctitle.png";

end;run;

/*proc template for powerpoint background image for all other slides*/

proc template;

define style styles.afgsc_slides;

parent=styles.powerpointlight;

class body /

backgroundimage="afgscppt.png";

end;run;

ods powerpoint style=styles.afgsc_title layout=titleslide;

proc odstext; /*title slide*/

p "Working Group Tasks" / style=PresentationTitle

style={fontweight=bold

foreground=blue

fontsize=44pt

/*font_style=italic*/};

run;

/****************at this point it, this proc odstext gets added to the above slide, but that's not what I want************/

ods powerpoint (sytle=styles.afgsc_slides);

proc odstext;

p "The ODS Destination for PowerPoint" / style=PresentationTitle

style={fontweight=bold

foreground=blue

fontsize=32pt

font_style=italic};

p "SAS Global Forum 2013" / style=PresentationTitle2;

run;

proc report data=sashelp.class;

column sex n;

define sex / group;

run;

ods powerpoint close;

So, what'd I'd like this to do is:

1) Title slide with it's own background image and title text.

2) Next slide with it's own background image and seperate proc odstext

Is ods powerpoint have that 'next page' ability on odstext?

And, does anyone use a better way to output to Powerpoint, I've read some articles on DDE to export data, charts, etc, however it seems somewhat tedious, but more flexible.

Re: ODS Powerpoint question

Cynthia_sas — Sun, 10 Aug 2014 03:20:55 GMT

Hi:

That's a very interesting question. Usually, with a question like this, I ask myself can I do xyz in abc product when SAS is not in the mix? So I went to PowerPoint and I tried to make a PPT deck that had 1 background for 1 slide and a different background for the rest of the slides, and I don't see how to do that. I can select a blank presentation to start and then I can select Slide Master to apply a background, but in PPT, without SAS involved, the background style that I select applies to the whole presentation. I can't have one background on the title slide and a different background on the other slides. I suppose I can create my own theme, but that is within PPT, not within SAS.

So, my guess is that if you can't do it in PowerPoint -- just in PowerPoint -- by itself, then SAS can't do it either. But, ultimately, I think you have a question or two for Tech Support.

cynthia

Also, the default for PROC ODSTEXT is for the PAGEBREAK option to be set to NO. Have you tried using PAGEBREAK=yes, as shown in the doc?

SAS(R) 9.4 Output Delivery System: Procedures Guide (ODSTEXT doc) Following the doc resulted in 2 slides when I ran the code below.

ods _all_ close;

options nodate;

title 'Using PROC ODSTEXT';

footnote 'The ODS Destination for PowerPoint';

ods powerpoint file="c:\temp\use_pgbreak.ppt" ;

proc odstext;

p 'Twas brillig and the slithy toves.';

p 'Did gyre and gimble in the wabe' / style=[color=red fontsize=25pt];

p 'All mimsy were the borogroves.' / style=[color=purple fontsize=30pt];

p 'And the mome raths outgrabe.' / style=[color=purple fontsize=30pt];

run;

proc odstext pagebreak=yes;

p 'Beware the Jabberwock my son!';

p 'The jaws that bite the claws that snatch' / style=[color=red fontsize=25pt];

p 'Beware the Jubjub bird and shun' / style=[color=purple fontsize=30pt];

p 'The frumious Bandersnatch' / style=[color=purple fontsize=30pt];

run;

ods _all_ close;