topic Re: Create table showing last friday of month in SAS Procedures

Create table showing last friday of month

brophymj — Fri, 01 Aug 2014 10:43:16 GMT

I'm trying to create a macro that creates a table showing the last Friday of every month. The table will look like this:

So, if i select a range of years, say 2001 to 2013 it will create a table like this:

YEAR	MONTH	LASTFRIDAY
2013	02	22
2013	03	29
2013	04	26
2013	05	...
2013	06	...
2013	07	...
2013	08	...
...	...
...	...

including all the years in the range I specify.

Re: Create table showing last friday of month

RW9 — Fri, 01 Aug 2014 10:50:37 GMT

Hi,

You would be best served using the interval functions an example is here:

SAS/ETS(R) 9.2 User's Guide

Re: Create table showing last friday of month

data_null__ — Fri, 01 Aug 2014 12:03:45 GMT

This seem reasonable, I always have to experiment with shifted intervals a bit before I can figure it. Find the last day of the month then find the first day of the week that "begins" on Friday "WEEK.6".

data friday;
   do year=2001 to 2013; 
      do month = 1 to 12; 
         b = mdy(month,1,year);
         e = intnx('Month',b,0,'E');
         f = intnx('week.6',e,0,'B');
         output; 
         end; 
      end; 
   format b e f weekdate.; 
   run; 
proc print; 
   run;

Re: Create table showing last friday of month

cov_derek — Fri, 01 Aug 2014 14:02:36 GMT

data _null_, shifted intervals are easy if you remember that interval.1 is the same as interval. It only gets complicated when you have large multipliers.

Re: Create table showing last friday of month

Ksharp — Fri, 01 Aug 2014 14:06:13 GMT

NULL,

Don't forget function nwkdom( ) .

data friday;
   do year=2001 to 2013; 
      do month = 1 to 12; 
           date=nwkdom(5,6,month,year);
           output; 
         end; 
      end; 
   format date weekdate.; 
   run;

Xia Keshan