topic Re: label name display in output in SAS Procedures

label name display in output

deleted_user — Tue, 14 Apr 2009 22:49:17 GMT

How can I display the entire name of my variables when they are in output. For example in my data step I put
if sex = 'M' then gender = 'male';
if sex = 'F' then gender = 'female';
if sex = 'U' then gender = 'unknown';

when this was outputed it showed up as
gender
fema
male
unkn

How can I get the entire word to show up in the output?

Re: label name display in output

DanielSantos — Wed, 15 Apr 2009 07:25:04 GMT

Actually, I think the data is correctly displayed...

I suspect you have created the GENDER variable in the input dataset without preassigning to it, the maximum possbible length.
You see, if you do not explicitly define a variable size, SAS will assume one of two things.
If it is a numerical var, it will be defined with the maximum length, being 8 bytes.
If it is a character var, it will be defined with the size of the first value assigned to it during execution.

In your case, I suspect the first value assigned to GENDER was 'male' which is 4 bytes long. From there, all other values where truncated to that size.

For example,

data YOURDATA;
GENDER='male'; output; /* first assignment defines variables size = 4 bytes */
GENDER='female'; output; /* truncated, GENDER='fema' */
GENDER='unknown'; output; /* truncated, GENDER='unkn' */;
run;

to avoid this explicitly define the variable size with the LENGTH statement.

data YOURDATA;
length GENDER $7; /* define GENDER as a 7 byte char variable */
GENDER='male'; output;
GENDER='female'; output;
GENDER='unknown'; output;
run;

Greetings from Portugal.

Daniel Santos at www.cgd.pt

Re: label name display in output

LinusH — Wed, 15 Apr 2009 11:25:02 GMT

If you don't want to be concerned about column length, using a user defined format could be an alternative.

/Linus

Re: label name display in output

venkatesh — Wed, 15 Apr 2009 12:08:26 GMT

Hello Cg,

See the example.

data test;
input sex$ age;
cards;
m 25
f 60
f 56
m 65
u 52
;
proc format;
value $sexes m = 'male'
f = 'female'
u = 'unknown'
;
proc print;
format sex $sexes.;
run;

or
u can do as per daniel suggestion.