topic Re: Using Macro Variable that starts with "%" in a Title? in SAS Procedures

Using Macro Variable that starts with "%" in a Title?

grodman — Wed, 08 Jan 2014 22:21:23 GMT

Hello -

I have a report that dynamically runs a proc-report to produce ODS output. The columns of the report, and corresponding define statements, are dynamically populated depending on the columns that the user chooses. However, some of these columns need to have title that start with a "%". Using the code below, the program runs and builds the columns of the report, but when it tries to give the title of "%oftotal" to the column, the report breaks because it thinks it's looking for a macro called "oftotal". Is there a way to suppress this warning, or make it so that the variable gets resolved without trying to invoke the "oftotal" macro?

Please help!

data work.data;

infile datalines delimiter=',';

format value 5. name $25.;

input value name;

datalines;

5,%oftotal(2013)

;

run;

data _null_;

set work.data;

call symputx("sortvariable", name);

run;

proc report data=work.data;

columns value;

define value / "&name";

run;

Re: Using Macro Variable that starts with "%" in a Title?

art297 — Wed, 08 Jan 2014 23:10:45 GMT

I'm confused. You create a macro variable called &sortvariable, but then try to access a macro variable called &name.

Am I missing something here?

Re: Using Macro Variable that starts with "%" in a Title?

data_null__ — Wed, 08 Jan 2014 23:32:39 GMT

data work.data;
   infile datalines dsd; 
   informat value 5. name $25.; 
   input value name;
   call symputx("name", name);
   datalines; 
5,%oftotal(2013)
;;;;
   run; 

proc report data=work.data;
   columns value;
   define value / "%superQ(name)"; 
   run; 

Re: Using Macro Variable that starts with "%" in a Title?

grodman — Thu, 09 Jan 2014 16:44:49 GMT

I got it backwards... I am trying to access the "sortname" macro variable... change is shown below.

data work.data;

infile datalines delimiter=',';

format value 5. name $25.;

input value name;

datalines;

5,%oftotal(2013)

;

run;

data _null_;

set work.data;

call symputx("sortvariable", name);

run;

proc report data=work.data;

columns value;

define value / "&sortvariable";

run;

Re: Using Macro Variable that starts with "%" in a Title?

grodman — Thu, 09 Jan 2014 16:45:13 GMT

This worked! Thank you very much!