topic declaring macro parameters in PROC SQL and length issues in SAS Procedures

declaring macro parameters in PROC SQL and length issues

LB — Mon, 04 Jun 2012 16:41:22 GMT

Hi all-

I have an issue that has been confounding me to no end-

I have a query that goes like this-

PROC SQL;

SELECT sum(CASE WHEN COMPLIANT='NO' then 1 else 0 END),count(*)

into :NUM1, :NUM2

from XYZ

where put(FAC_ID,$shortfix.)='XXX'

/*group by FAC_ID*/

quit;

When I call the macro variables NUM1 and NUM2, NUM1 has a big trailing space-

I have attempted to modify it as putting it as a character variable to no avail.

NUM2 works just fine.

Any answers, solutions would be great.

Thanks

Lawrence

Re: declaring macro parameters in PROC SQL and length issues

data_null__ — Mon, 04 Jun 2012 16:46:15 GMT

This should remove the spaces, I think....

%let num1=&num1;

%let num2=&num2;

%put NOTE: did it work **&num1** **&num2**;

Re: declaring macro parameters in PROC SQL and length issues

LB — Mon, 04 Jun 2012 16:51:47 GMT

Thanks data_null_!

That helped!

Lawrence

Re: declaring macro parameters in PROC SQL and length issues

MikeZdeb — Mon, 04 Jun 2012 17:11:46 GMT

hi ... you could also try ...

data x;

retain a b 5;

run;

proc sql noprint;

select a, b into :num1 separated by ' ', :num2 separated by ' ' from x ;

quit;

%put |&num1|&num2|;

|5|5|

from ...

http://www.sascommunity.org/wiki/Tips:Strip_Blanks_from_PROC_SQL-Created_Macro_Variable_Values

Re: declaring macro parameters in PROC SQL and length issues

Astounding — Mon, 04 Jun 2012 17:45:35 GMT

You've already gotten solutions. This is just for insight ...

Macro variables hold character strings only. When SQL extracts a numeric value, and the into : operator requests that it be stored in a macro variable, SQL has to perform a numeric to character conversion. Off the top of my head it uses an 8-character width, rather than the 12-character width that CALL SYMPUT would use. However, unlike a DATA step, SQL doesn't give you a note that conversion is taking place. At any rate, the blanks you are witnessing are leading blanks (for both variables), rather than trailing blanks, produced by the conversion process.

Good luck.

Re: declaring macro parameters in PROC SQL and length issues

LB — Mon, 04 Jun 2012 22:09:53 GMT

Astounding-

Thanks for the tip. That helps.

Lawrence

Re: declaring macro parameters in PROC SQL and length issues

PGStats — Tue, 05 Jun 2012 02:12:25 GMT

Or...

data x;
retain a b 555555555555;
format b best15.;
run;

proc sql noprint;
select a, b into :num1 trimmed, :num2 trimmed from x ;
quit;

%put |&num1|&num2|;

|5.556E11|555555555555|

Re: declaring macro parameters in PROC SQL and length issues

data_null__ — Tue, 05 Jun 2012 02:27:30 GMT

What version of SAS are you using? That doesn't work with my SAS 9.2.

Re: declaring macro parameters in PROC SQL and length issues

Linlin — Tue, 05 Jun 2012 02:42:10 GMT

Hi Data _null_,

It works with my SAS 9.3.

6 proc sql noprint;

7 select a, b into :num1 trimmed, :num2 trimmed from x ;

8 quit;

NOTE: PROCEDURE SQL used (Total process time):

real time 0.00 seconds

cpu time 0.00 seconds

10 %put |&num1|&num2|;

|5.556E11|555555555555|