topic Re: Reading concatenated MVS datasets from pc-SAS in SAS Procedures

Reading concatenated MVS datasets from pc-SAS

marka — Mon, 13 Apr 2009 20:58:11 GMT

On the mainframe (MVS) I know how to read in multiple datasets using the concatenated DD stmt. Is there something similar for pc-SAS (Windows) when reading MVS datasets using the FILENAME FTP statement?

Re: Reading concatenated MVS datasets from pc-SAS

sbb — Mon, 13 Apr 2009 22:11:29 GMT

Not that I'm aware of - the ability to concatenate files is within the FILENAME specification and enclosing your quoted files in parentheses. I don't expect that you can open two concurrent FTP connections as a concatenation.

Scott Barry
SBBWorks, Inc.

Re: Reading concatenated MVS datasets from pc-SAS

marka — Tue, 14 Apr 2009 13:15:35 GMT

Thanks

Re: Reading concatenated MVS datasets from pc-SAS

Peter_C — Tue, 14 Apr 2009 15:49:05 GMT

don't give up just yet.
The syntax definition allows concatenation within the filename statement.
I just had some success with code like[pre]filename fcont ftp ("'AUP.SREED.ACT.AVP.PETER(H)'"
"'AUP.SREED.ACT.AVP(EXIST)'" )
user= 'your user ID'
prompt /*for password*/
HOST='your hostname'
;
data _null_ ;
length filen $200 ;
infile fcont filename= filen ;
input ;
if filen ne lag(filen) then put filen= ;
put _infile_ ;
run ; [/pre]PeterC

Re: Reading concatenated MVS datasets from pc-SAS

data_null__ — Tue, 14 Apr 2009 17:15:26 GMT

The EOV INFILE statement option provides a more general method for concatenation boundary detection. Using changes to the value of FILENAME would not work if the files have the same name by design or accident when FILENAME is defined with improper attributes.

[pre]
filename FT15F001 temp;
parmcards;
Use EOV
1
2
3
4
5
;
run;

filename FT30F001 ("%sysfunc(pathname(ft15f001))" "%sysfunc(pathname(ft15f001))" "%sysfunc(pathname(ft15f001))");
data _null_;
length filename $100;
infile FT30F001 eov=eov filename=filename;
input;
if _n_ eq 1 or EOV then do;
put 'NOTE: ' _n_= filename=;
eov = 0;
end;
run;[/pre]

Re: Reading concatenated MVS datasets from pc-SAS

marka — Fri, 08 May 2009 19:27:46 GMT

Thanks, this works great!