topic Re: How to make a summary table? in SAS Procedures

How to make a summary table?

thdang — Fri, 09 Nov 2012 20:20:48 GMT

Hi, how can I make a summary table like this one:

mean median min max std

var1 a b c d e

var2 f g h i j

var3 k l n o p

where a,b,c,... is calculated. Now i only have it as one row. also, for the median I have instead of just 1 number a lot of number (all the number of that column).

Thank you very much!

Re: How to make a summary table?

art297 — Fri, 09 Nov 2012 20:31:35 GMT

It would help to see either your data or a subset of it. However, what you are looking for is probably proc means.

Take a look at: http://support.sas.com/documentation/cdl/en/proc/61895/HTML/default/viewer.htm#a000146729.htm

Re: How to make a summary table?

Reeza — Fri, 09 Nov 2012 20:35:24 GMT

If you have version 9.3 then try the following:

proc means data=sashelp.class stackods;

var height weight age;

output out=sample_summary;

run;

Re: How to make a summary table?

thdang — Fri, 09 Nov 2012 22:30:21 GMT

but those means are weighted means. so just want to get the layout or is that also possible to do the weighted means with the proc means

Re: How to make a summary table?

art297 — Fri, 09 Nov 2012 23:08:17 GMT

Why do you say they are weighted means? They would only be weighted means if a weight statement was included for the proc.

Re: How to make a summary table?

thdang — Fri, 09 Nov 2012 23:23:35 GMT

I mean that the means i want to calculate in my table are weighted mean. So if i do 'proc mean' i would get the normal means right. So i wonder if i can have the weighted means by using 'proc means'.

Re: How to make a summary table?

art297 — Sat, 10 Nov 2012 00:13:48 GMT

Yes. You simply have to include a statement like:

proc means data=sashelp.class stackods;

var height weight;

/*->*/ weight age;

output out=sample_summary;

run;

Re: How to make a summary table?

thdang — Sat, 10 Nov 2012 11:19:22 GMT

proc means data=sasdata.have;

var avg_return avg_expense avg_turnover ;

weight weights;

output out= sasdata.summary_statistics;

run;

"stackods" did not work for me, i think because i have version 9.2. but i don't have the median in the table

Re: How to make a summary table?

art297 — Sat, 10 Nov 2012 14:34:06 GMT

You have to declare the statistics that you want. e.g.:

proc means data=sashelp.class min max mean median stackods;

var height weight;

weight age;

output out=sample_summary median= mean= min= max= stddev= /autoname;

run;

Re: How to make a summary table?

thdang — Sat, 10 Nov 2012 15:02:02 GMT

Thank you for your help!!

Re: How to make a summary table?

Ksharp — Mon, 12 Nov 2012 02:24:39 GMT

Very interesting thing, Although the output of proc means looks good , but output dataset does not look right.

filename  x temp;
proc printto print=x; run;
proc means data=sashelp.class min max mean median ;
  var height weight;
  weight age;
run;
proc printto;run;
data want;
 infile x firstobs=7;
 input variable : $40. @;
 if variable not eq: '--' then do;input min max mean median; output;end;
run;

Ksharp

Re: How to make a summary table?

art297 — Mon, 12 Nov 2012 03:57:26 GMT

: What doesn't look right to you?

Re: How to make a summary table?

Ksharp — Mon, 12 Nov 2012 05:37:47 GMT

ArthurT,

My SAS9.2 can't work with option stackods . It looks like ,which might not be what OP want.

Re: How to make a summary table?

data_null__ — Mon, 12 Nov 2012 12:05:21 GMT

I think with 9.2 "you" will need to fiddle with the output to get what the OP is looking for.

proc SUMMARY data=sashelp.class;
   var height weight age;
   output out=summary median= mean= min= max= stddev= /autoname; 
   run; 
proc transpose data=summary(drop=_type_ _freq_) out=tall;
   run; 
data tall;
   set tall;
   length variable $32; 
   _ = find(_name_,'_',-32);
   variable = substr(_name_,1,_-1);
   _name_ =   substr(_name_,_+1);
   run; 
proc sort; 
   by variable;
   run; 
proc transpose data=tall out=notsotall;
   by variable;
   var col1;
   run;

Re: How to make a summary table?

thdang — Thu, 15 Nov 2012 22:10:45 GMT

Can I also make summary tables by five year interval (i.e 1980,85,90,95,00..) including the number of unique id in those years? Thank you very much.

Re: How to make a summary table?

art297 — Thu, 15 Nov 2012 22:24:15 GMT

You can add one or more 'by' variables to almost every SAS proc.

Re: How to make a summary table?

Reeza — Thu, 15 Nov 2012 22:28:43 GMT

If you're doing unique counts you probably want to look at proc freq or proc sql with count distinct instead of proc means.

Generally its a two step proc freq procedure or a single proc sql procedure. Depending on the data of course.

Re: How to make a summary table?

thdang — Thu, 15 Nov 2012 22:38:52 GMT

Thank you. But what I also mean is that before I have 1 summary table for the whole data set (30 years of data). Is that also possible to have several tables of summary each for 5 years interval (thus 6 tables)?

Re: How to make a summary table?

Reeza — Thu, 15 Nov 2012 23:04:49 GMT

Then Art is correct, add a by statement.

Re: How to make a summary table?

art297 — Thu, 15 Nov 2012 23:06:49 GMT

You will probably also need a format to define your groups. If you use a by statement you will get the desired groupings. If you use a class statement instead (i.e., replace the word by with the word class), you will get an extra line that shows the grand totals:

data have;

do year=1983 to 2012;

do i=1 to 19;

set sashelp.class point=i;

output;

end;

stop;

run;

proc format;

value years

1983-1987='1983-1987'

1987-1992='1987-1992'

1993-1997='1993-1997'

1998-2002='1998-2002'

2003-2007='2003-2007'

2008-2012='2008-2012'

;

run;

proc means data=have min max mean median stackods;

var height weight;

weight age;

by year;

format year years.;

output out=sample_summary median= mean= min= max= stddev= /autoname;

run;