topic Re: Determine top five winners in a series of races in SAS Procedures

Determine top five winners in a series of races

NKormanik — Fri, 26 Apr 2013 22:39:55 GMT

Suppose we have 100 runners. And they run 100 races. All we are given is the order that the racers come in, 1 through 100.

At the end of the race series what would be the fairest way to determine the top five winners?

What SAS procedure might one use to arrive at the solution?

We have 100 lists, of results. All lists numbered 1 to 100. A different ordering of names on each list, depending on the place they finish each race. We concatenate horizontally and come up with one large spreadsheet. Here would be a small sample of the spreadsheet:

Order Finished	Race 1	Race 2	Race 3
1	D	A	D
2	A	D	B
3	C	B	A
4	B	C	C

The whole spreadsheet is 100 x 100. Let's assume that all runners run in all races.

Any help and insights greatly appreciated.

Nicholas Kormanik

Re: Determine top five winners in a series of races

Reeza — Sat, 27 Apr 2013 01:09:24 GMT

Add rank by person over all races, persons with the 5 lowest rank are the top 5.

data input;

input rank race1 $ race2 $ race3 $;

cards;

1 D A D

2 A D B

3 C B A

4 B C C

;

run;

proc transpose data=input out=data1 ;

by rank;

var race1 race2 race3;

run;

proc means data=data1 sum noprint;

ways 1;

class col1;

var rank;

output out=summary1 sum(rank)=total;

run;

proc sort data=summary1;

by total ;

run;

Re: Determine top five winners in a series of races

NKormanik — Sat, 27 Apr 2013 07:05:53 GMT

Reeza, expertly done. Thank you so very much. I'll leave the question unanswered until tomorrow night in case anyone else has something more to add.

For now, though, you're the champ!

Re: Determine top five winners in a series of races

Ksharp — Sat, 27 Apr 2013 09:21:34 GMT

I would suggest principal component analysis . make the data like these and get the final score for every competitor based on the first two principal components.

race1 race2

A (the score of winning the champion has highest score)

Ksharp

Re: Determine top five winners in a series of races

NKormanik — Sat, 27 Apr 2013 14:38:37 GMT

Ksharp, why PCA as opposed to what Reeza has done?

Would you please write the complete code for the simple example above so one can compare?

Reeza's code seems to work flawlessly (copy and paste right into SAS). It would be interesting to see if PCA comes up with a different result.

Re: Determine top five winners in a series of races

Ksharp — Sat, 27 Apr 2013 15:10:50 GMT

Oh. Sorry . That doesn't matter whether the champion has highest score or lowest score. only if they has the same directory.

I used multi-variable analysis, not like Reeza , Principal Component Analysis will use the principal component of correlation matrix to explain the entire dataset data .

Or I want hear the opinion from Dr SteveDenham who is a statistical expert.

Ksharp

Re: Determine top five winners in a series of races

PGStats — Sun, 28 Apr 2013 03:37:13 GMT

Another scoring option is to look at who finished first the most often and to declare that runner the winner. If there is a tie, look among the ties who finished second the most often, and so on. This ranking is not trivial to compute but I would rely on the absence of a documented maximum on the number of sorting (BY) variables in proc sort to do the job, as follows :

data input;
input rank (race1-race3) ($) ;
cards;
1 D A D
2 A D B
3 C B A
4 B C C
;

data list;
set input;
array race race:;
do _n_ = 1 to dim(race);
     name = race{_n_};
     output;
     end;
drop race:;
run;

proc freq data=list noprint;
table name*rank / sparse out=scores(drop=percent);
run;

proc transpose data=scores out=scoreTable(drop=_:) prefix=r_;
var count;
by name;
id rank;
run;

proc sort data=scoreTable; key r_: / descending; run;

proc print data=scoreTable(obs=5) obs="Final rank"; run;

Re: Determine top five winners in a series of races

NKormanik — Sun, 28 Apr 2013 06:22:18 GMT

Glad to see you back, PGStats.

What is the significance of "not trivial to compute"? Does that mean this will work for small data sets, but not large ones? (Worked just fine, by the way -- copied and pasted directly into SAS. Same result as Reeza's way.) Seems the key improvement would be in solving the issue of ties.

By the way, if any runner misses one race does that mean he's screwed for the series?

Do you have a view on the PCA approach Ksharp mentioned?

Thanks much!

Re: Determine top five winners in a series of races

Ksharp — Sun, 28 Apr 2013 09:50:02 GMT

Reeza 's method take every race as a single thing separately. It don't care the relations between races . E.X. someone who wins 50-meter will be more possible winning 100-meter. Multi-variable analysis take these data as a whole data ,use one or two principle componet to present this Matrix , and take care of this relationship between races.

Ksharp

Re: Determine top five winners in a series of races

Haikuo — Sun, 28 Apr 2013 13:45:44 GMT

HI ,

As being hinted by above multiple answers, especially the one from PG's vs. others, at current stage, your problem is more of the methodology question than a SAS one. For example, there are many different ranking (rating) system in the world of sport. In the real world, Racers are ranked by their absolute scores (Usain Bolt: 9.58 sec) instead of relative ones, which makes more sense if the measurements are controlled well. Giving the relative scores you have, you are looking at something similar to the ranking systems such as Tennis or Golf. Again, in the real world, the weight of scores barely spreads evenly (eg. PG suggested), take Golf for example, in a major tournament, if the Champion gets 1000, the quarter-final only gets 250. That being said, it is your call to come up whatever ranking system you think is reasonable for your problem, and SAS will surely take care of the rest mechanical part of job.

Haikuo

Re: Determine top five winners in a series of races

SteveDenham — Mon, 29 Apr 2013 13:28:36 GMT

This is an interesting problem. Suppose you have an entrant who never wins a race, yet finishes second in all one hundred races, while there are never more than three or four races won by any other individual. If I were ranking the runners, I would certainly rank the first one highest. Now, what sort of analysis would yield this? This is an example of 's principal components analysis. That method extracts the vectors that explain the greatest variation, in order. I would then pick the scores on the first component's loadings to get my rankings.

But since the variable is ordinal, rather than continuous, and there may be ties, I would explore PROC PRINQUAL, and in particular, look at Example 74.2 Principal Components of Basketball Rankings in the PRINQUAL documentation.

Steve Denham

Re: Determine top five winners in a series of races

Ksharp — Mon, 29 Apr 2013 14:01:49 GMT

Dr SteveDenham

I am glad to hear your explanation for this question and know a new proc to process Principal Component analysis.

I hope I have some time to learn statistical methods which I really am amazed.

Best.

Ksharp

Re: Determine top five winners in a series of races

NKormanik — Tue, 30 Apr 2013 00:57:58 GMT

Thanks very much for the lead. Tonight I'll be reading up on PROC PRINQUAL.

Now what's needed here is to come up with the SAS code using PROC PRINQUAL to solve the initial problem. I'm sure the same result will be had for this small test. Will be very interesting, though, to see how it works with the larger data set.

Re: Determine top five winners in a series of races

PGStats — Tue, 30 Apr 2013 01:40:45 GMT

Steve Denham wrote:

Now, what sort of analysis would yield this?

Actually, Reeza's ranking would yield that. With her total ranks method, the always-second runner would score 100*2 = 200 whereas no other runner would score lower than 4+96*3=292.

Re: Determine top five winners in a series of races

PGStats — Tue, 30 Apr 2013 01:47:31 GMT

In my experience, the first principal component when dealing with sufficiently regular variables is often the positively weighted sum of all variables, i.e. something similar to Reeza's ranking method.

Re: Determine top five winners in a series of races

PGStats — Tue, 30 Apr 2013 02:25:22 GMT

Note that you can get a large family of rankings in the following way. If you define

where Rij is the rank of runner i in race j and a monotone increasing function f then

will be a valid ranking. Expressed that way, Reeza's method is based on

and mine on

Re: Determine top five winners in a series of races

NKormanik — Tue, 30 Apr 2013 07:28:45 GMT

We still need the code for the original small test in the Proc PRINQUAL manner, to compare results with the other ways suggested. I read the Basketball example, and it appears to be very similar. The original data set would need to be transformed, though. Please include that as well in your code.

The approaches suggested by and by yielded the same results.

Thanks to for suggesting PCA to begin with.

Yes there are many different methodologies for determining rankings in sports. In the present circumstance, however, we are given this particular set of results, and must try to come up with the fairest conclusions.

Particular concerns include:

-- Ties. In a tie between S (Strong) and W (Weak), if S beat better opponents than W, seems the tie should be broken in the favor of S.

-- Individuals missing some races, though in the races he/she participated in did very well.

Re: Determine top five winners in a series of races

SteveDenham — Tue, 30 Apr 2013 11:08:21 GMT

PRINQUAL is not going to behave well at all with a 4x4 sample matrix, due to the lack of sample size, so I'm going to pass on writing code for something that needs more data to be valid. However, for the 100x100 situation, I would use the code for the basketball example, including the datasteps prior to calling the PROC. These address ties and missing values.

Steve Denham

Re: Determine top five winners in a series of races

NKormanik — Wed, 01 May 2013 07:08:24 GMT

Here is a transformed data set (thanks ), slightly expanded to include an additional runner, and some missing data (those runners missed a race). This is in line with the data format in the very similar example mentioned above by , Example 74.2 Principal Components of Basketball Rankings, SAS/STAT(R) 12.1 User's Guide.

Runner	Order_1	Order_2	Order_3
A	2	*	3
B	5	4	2
C	4	5	4
D	1	2	1
E	3	1	*

The Basketball example is quite complicated with parts I'm not familiar with. If one of you wants to take a crack at translating that example to fit the present one, that would be fantastic.

At least the data is now in the required format, a substantial step forward.

I'll continue working on it as well.

Re: Determine top five winners in a series of races

NKormanik — Thu, 02 May 2013 06:56:14 GMT

Here's the stripped down version of the example mentioned above. What's needed is to translate it for the data set we have:

proc means data=nicholas.bballm;

output out=nicholas.maxrank

max=mcsn mdurs mdurh mwas musa mspom mins mupi map mspoi;

run;

data nicholas.bball;

set nicholas.bballm;

if _n_=1 then set nicholas.maxrank;

array services[10] CSN--SportsIllustrated;

array maxranks[10] mcsn--mspoi;

keep School CSN--SportsIllustrated;

do i=1 to 10;

if services=. then services=maxranks+1;

end;

run;

ods graphics on;

proc prinqual data=nicholas.bball out=nicholas.tbball scores n=1 tstandard=z

plots=transformations;

transform untie(CSN -- SportsIllustrated);

id School;

run;

proc factor nfactors=1 plots=scree;

ods select factorpattern screeplot;

var TCSN -- TSportsIllustrated;

run;

proc sort;

by Prin1;

run;

proc print;

var School Prin1;

run;