topic Re: verify function to extract number for a string in SAS Procedures

verify function to extract number for a string

michtka — Mon, 21 May 2012 21:11:04 GMT

Hi guys, can anyone help me to use the function verify to extract the number for the character variable code?

data new;

input code $;

datalines;

agsadg1

iuyasd2

flgdfe3

gttret4

hgtmgt5

gftfrg6

frgdf11

ewtdf54

ltrgr230

tyuf546

ffr1345

fgh5890

lko9999

;

run;

the idea is, generate a variable coden with the values:

230

546

1345

5890

9999

and I would like to use the function verify to do this.

Thanks in advance.

Re: verify function to extract number for a string

FriedEgg — Mon, 21 May 2012 22:13:30 GMT

data new;

input code $;

/* substr + verify */

want=substr(code,verify(lowcase(code),'abcdefghijklmnopqrstuvwxyz'));

/* compress */

want2=compress(code,,'kd');

/* prx (there are plenty of other ways too */

want3=prxchange('s/\D//o',-1,code); *remove any non-digit;

want4=prxchange('s/[A-Z]+//io',1,code); *remove a single string of alphabetic characters;

/* scan - this would be my preferred method */

want5=scan(code,-1,,'a');

datalines;

agsadg1

iuyasd2

flgdfe3

gttret4

hgtmgt5

gftfrg6

frgdf11

ewtdf54

ltrgr230

tyuf546

ffr1345

fgh5890

lko9999

;

run;

Re: verify function to extract number for a string

ballardw — Mon, 21 May 2012 22:23:10 GMT

if you want a numeric coden:

check = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ';

coden = input(substr (code,verify((upcase(code)),check)),best12.);

drop check;

if a string with numbers only:

check = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ';

coden = substr (code,verify((upcase(code)),check));

drop check;

Re: verify function to extract number for a string

Haikuo — Mon, 21 May 2012 22:26:36 GMT

Compress() can do the trick as well:

data new;

input code $;

n_code=compress(code,,'kd');

datalines;

agsadg1

iuyasd2

flgdfe3

gttret4

hgtmgt5

gftfrg6

frgdf11

ewtdf54

ltrgr230

tyuf546

ffr1345

fgh5890

lko9999

;

proc print;run;

Haikuo

Re: verify function to extract number for a string

Astounding — Mon, 21 May 2012 22:56:02 GMT

Is it possible you will have an embedded digit that you wish to ignore? For example, could this appear in your data:

hgt3mgt5

If so, would you like "5" as the result?

Re: verify function to extract number for a string

michtka — Tue, 22 May 2012 16:21:08 GMT

Thanks guys, It works.

Astoundind raised a good question....how i can ignore an embedded digit?...it can be a rare case, but how can I get

then 5 instead of 35?

any suggestion?

Re: verify function to extract number for a string

Astounding — Tue, 22 May 2012 16:55:32 GMT

There might be an easier way, especially when specifying the third parameter, but here's what comes to mind (untested):

length newcode $ 8;

newcode = scan(code, -1, compress(code,,'d'));

Re: verify function to extract number for a string

Linlin — Tue, 22 May 2012 17:57:49 GMT

tested code:

data new;

input code $;

datalines;

agsadg1

2uyasd2

flgdfe3

gttret4

hgtmgt5

gftfrg6

frgdf11

ewtdf54

ltrgr230

tyuf546

ffr1345

fgh5890

lko9999

hgt3mgt5

;

run;

data wnat;

set new;

n_code=substr(code,anyalpha(code,-length(code))+1);

proc print;run;

Obs code n_code

                                        1    agsadg1      1
                                        2    2uyasd2      2
                                        3    flgdfe3      3
                                        4    gttret4      4
                                        5    hgtmgt5      5
                                        6    gftfrg6      6
                                        7    frgdf11      11
                                        8    ewtdf54      54
                                        9    ltrgr230     230
                                       10    tyuf546      546
                                       11    ffr1345      1345
                                       12    fgh5890      5890
                                       13    lko9999      9999
                                       14    hgt3mgt5     5

Re: verify function to extract number for a string

Ksharp — Wed, 23 May 2012 03:15:48 GMT

There are lots of modifiers in SCAN(), You don't need a extra compress any more.

newcode = scan(code, -1,,'kd');

Re: verify function to extract number for a string

michtka — Thu, 31 May 2012 09:36:26 GMT

Sorry Ksharp, I just type your code but it doesnt work.

At the moment:

newcode = scan(code, -1, compress(code,,'d'));

n_code=substr(code,anyalpha(code,-length(code))+1);

works fine.

Have you tested it in my new dataset?

cheers,

Re: verify function to extract number for a string

Alpay — Thu, 31 May 2012 13:42:42 GMT

The way I understood the question is that you are looking for digits only placed at the end of a string.

If there is a digit between any two characters those digits are excluded.

Regular expressions might do the trick here as follows:

If there is a pattern of 1 or more characters, "[a-z]+", followed by 0 or more digits, "\d*", followed by 1 or more characters, "[a-z]+", replace them with null space, "//".

Zafer

data new;

input code $;

n_code=prxchange('s/[a-z]+\d*[a-z]+//',-1,code);

datalines;

agsadg1

iuyasd2

flgdfe3

gttret4

hgtmgt5

gftfrg6

frgdf11

ewtdf54

ltrgr230

tyuf546

ffr1345

fgh5890

lko9999

;

proc print;run;

Re: verify function to extract number for a string

Ksharp — Fri, 01 Jun 2012 01:55:52 GMT

Yes. My code is also right.

data new;
input code $;
newcode = scan(code, -1,,'kd');
datalines;
agsadg1
iuyasd2
flgdfe3
gttret4
hgtmgt5
gftfrg6
frgdf11
ewtdf54
ltrgr230
tyuf546
ffr1345
fgh5890
lko9999
;
run;

Ksharp

Re: verify function to extract number for a string

michtka — Fri, 01 Jun 2012 08:43:44 GMT

newcode = scan(code, -1,,'kd');

159

ERROR 159-185: Null parameters for SCAN are invalid.

Hi Ksharp, I got that error when I run your code using SAS 9.1.3

Re: verify function to extract number for a string

Ksharp — Fri, 01 Jun 2012 08:52:02 GMT

OU, I know the reason why you can't run it.

You are using SAS9.1.

You can't use my code ,then recommend to HaiKuo's code which is good.

Ksharp