topic Re: How to get the number of variables in one list? in SAS Procedures

How to get the number of variables in one list?

MikeTurner — Fri, 18 May 2012 08:28:32 GMT

If I create one variable list like this,

%let varlist=c1-c9;

How to get the number of variables in &varlist?

If I %let n=%sysfunc(countw(&varlist)), &n will be 2.

Any way to get the exact number of variables in &varlist?

Thanks!

Re: How to get the number of variables in one list?

Ksharp — Fri, 18 May 2012 09:19:29 GMT

How about :

%let varlist=c1-c9;

%let start=%scan(&varlist,1, ,kd);

%let end=%scan(&varlist,-1, ,kd);

%let n=%eval(&end-&start+1) ;

%put &n ;

Ksharp

Re: How to get the number of variables in one list?

Ksharp — Fri, 18 May 2012 09:21:26 GMT

Second way :

%let varlist=c1-c9;

data _null_;
array a{*} &varlist;
call symputx('n',dim(a));
stop;
run;
%put &n ;

Ksharp

Re: How to get the number of variables in one list?

MikeTurner — Fri, 18 May 2012 09:40:43 GMT

Thank you, Ksharp!

Re: How to get the number of variables in one list?

MikeTurner — Fri, 18 May 2012 09:46:01 GMT

Another question.

%let varlist=c1-c4 d1 d9;

How can I get the variable name list like c1 c2 c3 c4 d1 d9?

Thanks!

Re: How to get the number of variables in one list?

data_null__ — Fri, 18 May 2012 10:53:30 GMT

proc transpose data=have(obs=0) out=varlist;

var c1 c2 ..... ; * any list of variables that exist in have;

run;

You get a SAS data set and you can use it to answer all kinds of questions including how many.

Re: How to get the number of variables in one list?

Ksharp — Fri, 18 May 2012 11:17:29 GMT

Acutally NULL has already given you a good solution.

%let varlist=c1-c4 d1 d9;

data _null_;
length list $ 200;
array a{*} &varlist;
do i=1 to dim(a);
 list=catx(' ',list,vname(a{i}));
end;
call symputx('list',list);
stop;
run;
%put &list ;

Ksharp