topic Re: proc means output in SAS Procedures

proc means output

Hawkeye — Tue, 24 Jul 2012 18:45:20 GMT

I am trying to get specific options in my output namely q1 q3 and qrange, however it will only put the standard proc means statistics in my file. Currently my code looks like this

proc means data = data Q1 Q3 qrange/*mean std min max n qrange*/ maxdec = 3;
    output out = data2 q1 autoname;
run;

/* Where data is any dataset and data2 is the output.*/

Originally I had tried to output the file as an ods html file but when I tried to re-read in the file it started taking all of the settings of the html file when reading the file.

Re: proc means output

PaigeMiller — Tue, 24 Jul 2012 18:54:20 GMT

I don't think your output statement syntax is correct.

Something like this ought to work

OUTPUT OUT=DATA2 q1=q1 q3=q3 qrange=qrange;

Re: proc means output

Linlin — Tue, 24 Jul 2012 19:07:47 GMT

example:

proc means data = sashelp.class noprint;

var weight height;

OUTPUT OUT=DATA2 q1= q3= qrange=/autoname ;

run;

proc print data=data2;run;

Linlin

Re: proc means output

Hawkeye — Tue, 24 Jul 2012 19:12:35 GMT

Is there anyway that I can get it to look like the output from the proc means statement. It is all in one column right now.

Re: proc means output

Linlin — Tue, 24 Jul 2012 19:43:55 GMT

example:

proc means data = sashelp.class noprint;
var age height ;
OUTPUT OUT=data2(drop=_:) q1= q3= qrange=/autoname ;
run;
data age(rename=(age_q1=q1 age_q3=q3 age_qrange=qrange));
set data2(keep=age:);
item='age';
data height(rename=(height_q1=q1 height_q3=q3 height_qrange=qrange));
set data2(keep=height:);
item='height';
data want;
length item $ 10;
set age height;
proc print;run;

Obs item q1 q3 qrange

1 age 12.0 15.0 3
2 height 57.5 66.5 9

Re: proc means output

Reeza — Tue, 24 Jul 2012 19:49:11 GMT

In one step....

proc means data=sashelp.class stackods q1 q3 qrange maxdec=3;

var age height;

ods output summary=sample_out;

run;

Re: proc means output

Linlin — Tue, 24 Jul 2012 19:55:46 GMT

Hi Reeza,

Nice! Thank you very much! - Linlin

Re: proc means output

Hawkeye — Tue, 24 Jul 2012 19:56:52 GMT

Yea something like that but really what I am looking for is how can I save the output as .csv file and have it look like the output that is in sas. Currently the way I am doing it is something like this

ods html file = '*filepath*.csv';
proc means data = data Q1 Q3 qrange/*mean std min max n qrange*/ maxdec = 3;
run;
quit;
ods html close;

However when I try to do that it gets exported as a html/csv file that is unable to be imported back into sas. The only way I can get it to work is by running half the program, opening the file in word saving it as a .csv and then continuing the code. What I need is to somehow be able to export the proc means as a .csv file and then reimport it without having to stop the code.

Re: proc means output

Hawkeye — Tue, 24 Jul 2012 20:00:52 GMT

That looks like it may work. I just tried to run what you posted but it said that there was a syntax error with "stackods".

Syntax error, expecting one of the following: ;, (, ALPHA, CHARTYPE, CLASSDATA, CLM, COMPLETETYPES, CSS, CV,

DATA, DESCEND, DESCENDING, DESCENDTYPES, EXCLNPWGT, EXCLNPWGTS, EXCLUSIVE, FW, IDMIN, KURTOSIS, LCLM, MAX,

MAXDEC, MEAN, MEDIAN, MIN, MISSING, MODE, N, NDEC, NMISS, NOLABELS, NONOBS, NOPRINT, NOTHREADS, NOTRAP, NWAY,

ORDER, P1, P10, P25, P5, P50, P75, P90, P95, P99, PCTLDEF, PRINT, PRINTALL, PRINTALLTYPES, PRINTIDS,

PRINTIDVARS, PROBT, Q1, Q3, QMARKERS, QMETHOD, QNTLDEF, QRANGE, RANGE, SKEWNESS, STDDEV, STDERR, SUM, SUMSIZE,

SUMWGT, T, THREADS, UCLM, USS, VAR, VARDEF.

ERROR 202-322: The option or parameter is not recognized and will be ignored.

Re: proc means output

Linlin — Tue, 24 Jul 2012 20:07:12 GMT

I have sas 9.3, no problem for me to run Reeza's code.

Re: proc means output

Hawkeye — Tue, 24 Jul 2012 20:08:02 GMT

I have sas 9.2 so maybe that is it? regardless I took out the stackods and it worked.

Edit: I have gotten that output before, but how can I get the variables to fall under each other?

Re: proc means output

Linlin — Tue, 24 Jul 2012 20:11:33 GMT

I would create a sas dataset first then create a csv file:

PROC EXPORT DATA= WORK.want

OUTFILE= "C:\TEMP\example.csv"

DBMS=CSV REPLACE;

PUTNAMES=YES;

RUN;

Re: proc means output

Linlin — Tue, 24 Jul 2012 20:23:21 GMT

then you have to do some data manipulation. using the code below as an example and changing the RED parts:

data age(rename=(age_q1=q1 age_q3=q3 age_qrange=qrange));

set data2(keep=age:);

item='age';

data height(rename=(height_q1=q1 height_q3=q3 height_qrange=qrange));

set data2(keep=height:);

item='height';

data want;

length item $ 10;

set age height;

run;

Re: proc means output

Linlin — Tue, 24 Jul 2012 20:32:59 GMT

with stackods you can get what you want in one step:

proc means data=sashelp.class stackods q1 q3 qrange maxdec=3;
var age height;
ods output summary=sample_out;
run;
proc print;run;

Obs Variable Q1 Q3 QRange

1 Age 12.000 15.000 3.000
2 Height 57.500 66.500 9.000

Re: proc means output

Cynthia_sas — Tue, 24 Jul 2012 21:28:42 GMT

Hi:

You've gotten a lot of good suggestions and if you want to stick with PROC MEANS, then STACKODS is the best solution, but it requires 9.3. So if you would be willing to switch procedures, PROC TABULATE will give you the output you want without manipulating the output dataset or using PROC EXPORT. See the code and results (for HTML and CSV) in the attached screenshot.

cynthia

Re: proc means output

Dorota_Jarosz — Wed, 25 Jul 2012 01:48:22 GMT

Expanding on Linlin's ideas and assuming SAS version 9.1 and no SAS/Access to PC Files:

proc means data = sashelp.class noprint;
var age ;
    OUTPUT OUT=dat1 (drop=_:) q1=q1 q3=q3 qrange=qrange ;
run;
proc means data = sashelp.class noprint;
var height ;
    OUTPUT OUT=dat2 (drop=_:) q1=q1 q3=q3 qrange=qrange ;
run;
proc means data = sashelp.class noprint;
var weight ;
    OUTPUT OUT=dat3 (drop=_:) q1=q1 q3=q3 qrange=qrange ;
run;
data want;
length item $ 10;
set dat1;
item="age";
output;
set dat2;
item="height";
output;
set dat3;
item="weight";
output;
run;
proc print;run;
*output:
Obs    item       q1      q3     qrange

1     age       12.0    15.0       3
2     height    57.5    66.5       9
3     weight    84.0    112.5     28.5
;

*old fashion CSV output to flat file;
filename csv "C:\temp\Quartiles.csv";
data _null_;
set want;
file csv;
if _n_=1 then
put @1 "Variable,"
    @12 "q1,"
    @22 "q3,"
    @32 "qrange"
    ;
put @1 item      ","
    @12 q1 best8. ","
    @22 q3 best8. ","
    @32 qrange best8.
    ;
run;

Re: proc means output

MikeZdeb — Thu, 26 Jul 2012 02:26:36 GMT

hi ... rather than use a data step to assemble the data after MEANS, how about using a data step prior to SUMMARY and running it once ...

data class (keep=variable value) / view=class;

set sashelp.class;

array nm(*) _numeric_;

do j=1 to dim(nm);

variable = vname(nm(j));

value = nm(j);

output;

end;

run;

proc summary data=class nway;

class variable;

var value;

output out=stats (drop=_:) q1=q1 q3=q3 qrange=qrange;

run;

variable q1 q3 qrange

Age 12.0 15.0 3.0

Height 57.5 66.5 9.0

Weight 84.0 112.5 28.5

* create CSV file without ACCESS to PC Files module;

ods csv file='z:\stats.csv';

proc print data=stats noobs;

run;

ods csv close;

Re: proc means output

Dorota_Jarosz — Thu, 26 Jul 2012 04:37:40 GMT

Thank you, MIke. I really like your solution. My mind is still in the mainframe and flat file mode.

Re: proc means output

Hawkeye — Wed, 08 Aug 2012 20:05:37 GMT

I ended up geting sas 9.3 so I was able to use the stackods option, thank you all for the help.