topic Re: Calculate percentage of 2 column in SAS Procedures

Calculate percentage of 2 column

Arumugam — Fri, 20 Jul 2012 01:13:42 GMT

te
I have a data like as below

Name prevrecord currrecord

A 10 25

B 20 15

C 40 20

My outputput should look like

Name prevrecord prevpct currrecord currpct

A 10 14.28 25 41.6

B 20 28.57 15 25

C 40 57.14 20 33.33

Prevpct and currpct is the percentage of corresponding column.Which procedure i can use to acheive this?

Thanks,

Mani

Re: Calculate percentage of 2 column

Linlin — Fri, 20 Jul 2012 01:27:57 GMT

data have;

input Name :$ prevrecord : currrecord;

cards;

A 10 25

B 20 15

C 40 20

;

proc sql;

create table want as

select name

,prevrecord

,prevrecord/sum(prevrecord)*100 format=5.2 as prevpct

,currrecord

,currrecord/sum(currrecord)*100 format=5.2 as currpct

from have;

quit;

proc print;run;

Linlin

Re: Calculate percentage of 2 column

Ksharp — Fri, 20 Jul 2012 03:21:27 GMT

proc tabulate data=have;

class name;

var prevrecord currrecord ;

table name,prevrecord*(sum colpctsum) currrecord*(sum colpctsum);

run;

Re: Calculate percentage of 2 column

Haikuo — Fri, 20 Jul 2012 03:41:29 GMT

The more, the merrier, here is a data step approach:

data want (drop=_:);

set have(in=up) have;

format prevpct currpct percent8.2;

if up then do;

_tp+prevrecord;

_tc+currrecord;

end;

else do;

prevpct=prevrecord/_tp;

currpct=currrecord/_tc;

output;

end;

run;

Haikuo

Re: Calculate percentage of 2 column

Arumugam — Fri, 20 Jul 2012 20:02:49 GMT

Thanks.It worked.