topic Re: How to create underlines for the external text lines in proc report compute block line statements? in SAS Procedures

How to create underlines for the external text lines in proc report compute block line statements?

alwaz_searching — Thu, 19 Jul 2012 15:00:27 GMT

I tried with the below code but could not get the text underlined into line statment:

proc report data=quart_report nowd split= '*'

style(lines)=[color=black backgroundcolor=white

fontsize=2 textalign=l]

;

column project dept cat;

by dept ;

define project / display style(column) =[cellwidth = 0.75in] ;

define dept / display style(column) =[cellwidth = 0.75in] ;

define cat / display style(column) =[cellwidth = 0.75in] ;

compute after _page_ ;

line ' ' ;

line @1 bold "^S={posttext='^-350x_____________________________________'}Available Categories:" ;

line ' ' ;

line @1 'DESCRIPTION' bold;

line ' ' ;

endcomp;

run;

Any other suggestions???

Re: How to create underlines for the external text lines in proc report compute block line statements?

Ksharp — Fri, 20 Jul 2012 02:47:36 GMT

What destination are you using ?

RTF use Raw Destination-Specific Codes .

'~R"\ul underlined text \ul0 "'

Ksharp

Re: How to create underlines for the external text lines in proc report compute block line statements?

Cynthia_sas — Fri, 20 Jul 2012 03:53:56 GMT

Hi:

The "raw" destination specific codes will work for RTF, but not for PDF or HTML. If you want a technique that would work for PDF, RTF or HTML, there is a new style attribute in 9.2 that will do underlining without the need for "raw" codes. The style attribute is TEXTDECORATION and something like this should work in RTF, PDF and HTML. Remember you will need your

ODS ESCAPECHAR='^';

statement first....then your compute block would be like what is shown below.

cynthia

ods escapechar='^';

ods html file='c:\temp\textdecoration.html' style=sasweb;

ods pdf file='c:\temp\textdecoration.pdf';

ods rtf file='c:\temp\textdecoration.rtf';

proc report data=quart_report nowd split= '*'

style(lines)=[color=black backgroundcolor=white

fontsize=2 fontweight=bold] ;

...more code ...

compute after _page_ /style={just=l};

line ' ' ;

line @1 "^{style[textdecoration=underline just=l]Available Categories:}" ;

line ' ' ;

line @1 '^{style[just=l]DESCRIPTION}';

line ' ' ;

endcomp;

run;

ods _all_ close;

Re: How to create underlines for the external text lines in proc report compute block line statements?

alwaz_searching — Wed, 25 Jul 2012 05:59:10 GMT

Hi Cynthia,

Thanks a lot!!!