topic Connect cell in column based on condition in SAS Procedures

Connect cell in column based on condition

bob021 — Thu, 24 Feb 2011 08:28:09 GMT

Hi
can somebody help me with this.
Data:

Name code operations CNT
Bob A 20 1
Bob B 20 2
Bob B 30 3
Bob D 40 4
John A 20 1
John A 20 2
John B 30 3
John C 30 4

What I want is to connect cell in column code(comma delimited) if name and operations are same like in example below:

Name code operations
Bob A,B 20
Bob B 30
Bob D 40
John A,A 20
John B,C 30

Thank you in advance
Bob Message was edited by: bob021

Re: Connect cell in column based on condition

Ksharp — Thu, 24 Feb 2011 09:52:48 GMT

OK. It is easy.
[pre]
data temp;
input Name $ code $ operations CNT;
cards;
Bob A 20 1
Bob B 20 2
Bob B 30 3
Bob D 40 4
John A 20 1
John A 20 2
John B 30 3
John C 30 4
;
run;
proc sort data=temp;
by name operations;
run;
data result;
set temp;
by name operations;
length _code $ 10;
retain _code;
if first.operations then call missing(_code);
_code=catx(',',_code,code);
if last.operations then output;
keep name _code operations;
run;
proc print;run;
[/pre]

Ksharp

Re: Connect cell in column based on condition

bob021 — Thu, 24 Feb 2011 10:13:08 GMT

Hello Ksharp
Thank you very much working like a charm.
Bob