topic Re: Data Tagging across time in SAS Procedures

Data Tagging across time

xchoit — Wed, 10 Apr 2013 08:44:18 GMT

How do I create a tagging (DelinquentTag) variable based on that 3 variables across time.

Example:

Data:

Date Accno Delinquent DelinquentTag

30Nov2011 123 0 N

31Dec2011 123 1 Y

31Jan2012 123 0 Y

30Nov2011 234 0 N

31Dec2011 234 0 N

30Nov2011 235 1 Y

31Dec2011 235 1 Y

Regards,

xchoit

Re: Data Tagging across time

LinusH — Wed, 10 Apr 2013 09:20:18 GMT

Do you want to mark all roes (for each accno) as "Y" from the record where delinquent is = 1, and thereafter?

You could archive this by using first.-logic together with the retain statement.

Re: Data Tagging across time

data_null__ — Wed, 10 Apr 2013 13:10:14 GMT

Once the acc becomes delinquent stop checking and "retain" true.

data acc;
   input Date:date. Accno:$3. Delinquent;
   format date date9.; 
   cards; 
30Nov2011     123          0               
31Dec2011     123          1               
31Jan2012      123          0              
30Nov2011     234          0               
31Dec2011     234          0               
30Nov2011     235          1               
31Dec2011     235          1               
;;;;
   run; 
data deliq;
   flag = 0; 
   do until(last.accno);
      set acc;
      by accno;
      if not flag then flag = ifn(Delinquent,1,0);
      output; 
      end; 
   run;