topic Re: PROC Report: Alternate shading for a group variable in SAS Procedures

PROC Report: Alternate shading for a group variable

Altal — Wed, 02 Oct 2013 18:57:44 GMT

Hello Community,

Is there any way in PROC REPORT to apply alternate shading of ALL rows of a group variable in ODS RTF? Something like the attached table...

I'm using this mock dataset to illustrate....

ods rtf file='C:\******.rtf' startpage=never BODYTITLE style=journal;

data have;

do month = 'Jan','Feb','Mar','Apr';

do dept= 'Assistants','IT','Dev';

do N= 1 to 10;output;

do salary=ranuni(737346) * 100000;output;

end;

run;

proc report data=have nowd headline;

column month dept salary;

define month/group width=7;

define dept/group;

define salary/ max;

run;

ods rtf close;

Re: PROC Report: Alternate shading for a group variable

data_null__ — Wed, 02 Oct 2013 19:41:50 GMT

This looks pretty close.

ods rtf file='~/altlightgrey.rtf' startpage=never BODYTITLE style=journal;
data have;
   do month = 'Jan','Feb','Mar','Apr'; 
      do dept= 'Assistants','IT','Dev'; 
         do N= 1 to 10;output; 
            do salary=ranuni(737346) * 100000; 
               output; 
               end; 
            end; 
         end; 
      end; 
   run; 


proc report data=have nowd headline; 
   column month dept salary;
   define month/group width=7; 
   define dept/group; 
   define salary/ max; 
   compute before month;
      I + 1; 
      endcomp; 
   compute salary;
      if mod(i,2) eq 1 

         then call define(_row_, "style", "STYLE=[background=lightgrey]");
      endcomp; 
   run; 

ods rtf close;

Re: PROC Report: Alternate shading for a group variable

Altal — Wed, 02 Oct 2013 19:53:42 GMT

Fantastic! Thanks very much data_null_ !