topic Re: call symput in SAS Procedures

call symput

Mike_Davis — Wed, 02 May 2012 14:39:22 GMT

Hello everybody,

How to use symput in data step to put a variable's each value of each oberservations into batch of macro variables?

data _null_;

set sashelp.class end=eof;

do until (eof);

call symput('aa'||_n_,sex);

end;

stop;

run;

%put &aa1 &aa2;

Mike_Davis — Wed, 02 May 2012 14:39:59 GMT

data _null_;

set sashelp.class end=eof;

*do until (eof);

call symput('aa'||left(_n_),sex);

*end;

*stop;

run;

%put &aa1 &aa2;

Linlin — Wed, 02 May 2012 14:59:17 GMT

data _null_;
set sashelp.class ;
call symputx(cats('aa',strip(_n_)),sex);
run;

%put _user_;

MikeZdeb — Wed, 02 May 2012 15:03:07 GMT

hi ... you might also consider SYMPUTX to reduce the length of the macro variables, for example ...

data _null_;

set sashelp.class (obs=2);

call symput(cats('aa',_n_),name);

call symputx(cats('bb',_n_),name);

run;

%put |&aa1| |&aa2|;

%put |&bb1| |&bb2|;

123 %put |&aa1| |&aa2|;

|Alfred | |Alice |

124 %put |&bb1| |&bb2|;

|Alfred| |Alice|

also, the various CAT functions do not give you log messages when concatenating numeric variables such as _N_

CATS applies STRIP to each argument so I don't think it's necessary to add the STRIP function within CATS

Linlin — Wed, 02 May 2012 17:18:56 GMT

Thank you Milke! It is good to know. - Linlin