topic Re: proc options question in SAS Procedures

proc options question

mnew — Sun, 10 Oct 2010 00:42:40 GMT

Experts:

If you only need to find out a few specific system options, what is the most efficient way?

I tried a couple ways and failed:
proc options option = pagesize option=linesize;
proc options options = pagesize linesize;

I studied the Help. The group = is certainly better than just proc options;
Any better ways?
Thank you!
the lazy beginner

Re: proc options question

piggy — Sun, 10 Oct 2010 04:56:59 GMT

proc options;
run;
can be used to check all default options.

Proc options
group =errorHandling;
Run ;

can be used to check certain group of options;

proc options option = pagesize ;
run;

can be used to check single option.

However, I am beginner too. Waiting for real expert to answer your question.

Re: proc options question

Robert_Bardos — Sun, 10 Oct 2010 07:59:08 GMT

If by 'specific' you mean that you exactly know the option's name then I prefer things like
[pre]
%* display selected options on log ;
%put %sysfunc(getoption(linesize,keyword)) ;
%put %sysfunc(getoption(pagesize,keyword)) ;
[/pre]
If you change these options within a SAS session (be it foreground or background) temporarily, good practice is to do it somewhat like
[pre]
%let _ls = %sysfunc(getoption(linesize,keyword)) ;
%let _ps = %sysfunc(getoption(pagesize,keyword)) ;
options linesize=200 pagesize=100 ; /* hypothetic values */
%* do some SAS things here ;
options &_ls &_ps ;
[/pre]
Alternatively you could use procedures OPTSAVE and OPTLOAD to front-end temporary modifications.

Re: proc options question

mnew — Sun, 10 Oct 2010 18:33:47 GMT

Thank you. There is so much to learn!

Re: proc options question

mnew — Sun, 10 Oct 2010 18:47:54 GMT

Great suggestions! Also helped me to learn more about SAS macro. (I've only read briefly about the topic before.) Thank you!

Re: proc options question

Peter_C — Mon, 11 Oct 2010 14:34:29 GMT

when wanting the value of system options, avoid typing with a macro like:
%macro sy(op) /des='get system option with keyword' ;
%sysfunc( getoption(&op, keyword))
%mend sy ;
then
%put %sy(ls) %sy(ps) %sy(sasautos);
becomes a concise and convenient way to check the value of an option (not much more than the option name itself !)
similarly
%let old_opts = %sy(mlogic) %sy(mprint) %sy(symbolgen) ;
provides a brief way to collect and store options before changing them, as you might want when you start some more macro development

learn the convenience of placing your macros in your sasautos folder and inserting your sasautos folder at the beginning of the SASAUTOS system option, with something like
option sasautos=( mymacros sasautos ) ;
in your autoexec.sas

good luck
peterC

Re: proc options question

mnew — Mon, 11 Oct 2010 15:18:19 GMT

Awesome. I'm going to file this one for the days when the word macro no longer intimidates me!

Re: proc options question

martha_sas — Tue, 12 Oct 2010 15:35:02 GMT

I'm replying to your original question.
Using proc options to check multiple formats is just fine. The first way you presented it is correct and will work. You said it did not work? (Your second method will produce an error. Since you didn't have "option=" before "linesize, SAS trys to interpret "linesize" as another option for the procedure and fails.)

You can also add the option 'value' and you will get more information, e.g.

proc options option=pagesize option=linesize value;
run;

Re: proc options question

mnew — Wed, 13 Oct 2010 05:03:40 GMT

Thank you for the reply. I double-checked. Here is the log I got. For some reason, only the value for second option comes back.

1 proc options option = pagesize option=linesize;
2 run;

SAS (r) Proprietary Software Release 9.2 TS2M2

LINESIZE=96 Line size for SAS log and SAS procedure output
NOTE: PROCEDURE OPTIONS used (Total process time):

3 proc options option = pagesize option=linesize value;
4 run;

SAS (r) Proprietary Software Release 9.2 TS2M2

Option Value Information For SAS Option LINESIZE
Option Value: 96
Option Scope: DMS Process
How option value set: Unknown
NOTE: PROCEDURE OPTIONS used (Total process time):

Re: proc options question

martha_sas — Wed, 13 Oct 2010 16:16:19 GMT

Now I know why it works for me and not you. You're running SAS 9.2m2 and I was using 9.3. At 9.2m2 you can only get information on one option at a time. At 9.3 there's more flexibility and you can even to this:
proc options option=(linesize pagesize);
But you can't do that at 9.2m2.

I didn't realize that until I saw your log which version you were using.

Re: proc options question

mnew — Thu, 14 Oct 2010 21:49:43 GMT

I see. I didn't consider the possibility of version difference at all. Thank you.

Re: proc options question

Ksharp — Mon, 18 Oct 2010 00:57:21 GMT

There is a dictionary table (dictionary.options) which can do the same thing.
[pre]
proc sql;
select optname,setting
from dictionary.options
where optname in ('LINESIZE' 'PAGESIZE' 'COMPRESS');
quit;

[/pre]

Ksharp

Re: proc options question

mnew — Tue, 19 Oct 2010 23:34:37 GMT

Thank you. Tried and it worked nicely.