topic Re: How do i asending the oder of n number of visit coloumn ? in SAS Procedures

How do i asending the oder of n number of visit coloumn ?

rohit_prajapati — Wed, 03 Oct 2012 11:27:14 GMT

Hi,

How do i asending the oder of n number of visit coloumn ?

Example:-

DATA VAR;

INPUT Subject $ VISIT1 VISIT3 VISIT2_01 VISIT2 VISIT3_02 VISIT3_01

DATALINES;

A0001 5 6 2 3 54 2

B0001 2 4 6 5 4 5

C0001 2 4 36 5 4 2;

run;

WANT -

oderwise variables-

Subject VISIT1 VISIT2 VISIT2_01 VISIT3 VISIT3_01 VISIT3_01

Regards,

Rohit

Re: How do i asending the oder of n number of visit coloumn ?

art297 — Wed, 03 Oct 2012 12:05:59 GMT

Since you appear to only want them sorted alphabetically, your easiest approach (I think) would be to use proc sql to generate the desired ordering, and then use that info in a retain statement. e.g.:

DATA VAR;

INPUT Subject $ VISIT1 VISIT3 VISIT2_01 VISIT2 VISIT3_02 VISIT3_01;

DATALINES;

A0001 5 6 2 3 54 2

B0001 2 4 6 5 4 5

C0001 2 4 36 5 4 2

;

run;

proc sql noprint;

select name

into :names separated by " "

from dictionary.columns

where libname eq "WORK" and

memname eq "VAR"

order by name

;

quit;

data want;

retain &names.;

set var;

run;

Re: How do i asending the oder of n number of visit coloumn ?

Amir — Wed, 03 Oct 2012 12:12:50 GMT

Hi Rohit,

Were you looking for something like the following:

DATA VAR;

length Subject $8

VISIT1 $8

VISIT2 $8

VISIT2_01 $8

VISIT3 $8

VISIT3_01 $8

VISIT3_02 $8

;

INPUT Subject $ VISIT1 VISIT3 VISIT2_01 VISIT2 VISIT3_02 VISIT3_01;

DATALINES;

A0001 5 6 2 3 54 2

B0001 2 4 6 5 4 5

C0001 2 4 36 5 4 2

;

run;

Regards,

Amir.

EDIT: I just realised you've probably been given the SAS data set in that order, so you can ignore my response if that's the case.

Message was edited by: Amir Malik

Re: How do i asending the oder of n number of visit coloumn ?

Patrick — Wed, 03 Oct 2012 12:15:39 GMT

The order of variables in a dataset should be irelevant - but here you go:

DATA VAR;
INPUT Subject $ VISIT1 VISIT3 VISIT2_01 VISIT2 VISIT3_02 VISIT3_01;
DATALINES;
A0001 5 6 2 3 54 2
B0001 2 4 6 5 4 5
C0001 2 4 36 5 4 2
;
run;

proc sql noprint;
   select name into :SortedVarList separated by ' '
   from dictionary.columns
   where libname='WORK' and memname='VAR' and upcase(name) like 'VISIT%'
   order by name
   ;
quit;

data VAR;
retain Subject &SortedVarList;
set var;
run;

Re: How do i asending the oder of n number of visit coloumn ?

kuridisanjeev — Wed, 03 Oct 2012 13:03:49 GMT

Hi Rohit.

similar kind question i posted long back...

Go through bellow link,you can find some other ways...

https://communities.sas.com/thread/32930

Regards...

Sanjeev.K

Re: How do i asending the oder of n number of visit coloumn ?

Ksharp — Thu, 04 Oct 2012 03:09:59 GMT

As Arthur and Patrick did, You can get whatever order you want by using SQL.

DATA VAR;
   INPUT Subject $ VISIT1 VISIT3 VISIT2_01 VISIT2 VISIT3_02 VISIT3_01;
   DATALINES;
A0001 5 6 2 3 54 2
B0001 2 4 6 5 4 5
C0001 2 4 36 5 4 2
;
run;

 

proc sql noprint;
   select name into :SortedVarList separated by ' '
   from dictionary.columns
   where libname='WORK' and memname='VAR' and upcase(name) like 'VISIT%'
   order by input(scan(name,1,'VISIT_'),best8.),input(scan(name,2,'VISIT_'),best8.)
   ;
quit;

%put &SortedVarList ;
 

data VAR;
   retain Subject &SortedVarList;
   set var;
run;

Ksharp