topic Re: How to transfer this dataset? in SAS Procedures

How to transfer this dataset?

rpg163 — Fri, 03 Aug 2012 15:23:52 GMT

Hi,

I have a dataset like this:

data A;

input code $ type $12.;

cards;

ASD1 6,8,14

ASD2 14

ASD3 4,8,14

ASD4 4,8,14

ASD5 14

ASD6 1,2,4,8,11

ASD7 5

ASD8 2,5

run;

How can I transfer this dataset to following form:

ASD1 6

ASD1 8

ASD1 14

ASD2 14

ASD8 2

ASD8 5

Thanks in advance for any help!

Re: How to transfer this dataset?

Linlin — Fri, 03 Aug 2012 15:38:56 GMT

data A;
    input code $ type $12.;
    cards;
    ASD1    6,8,14
    ASD2    14
    ASD3    4,8,14
    ASD4    4,8,14
    ASD5    14
    ASD6    1,2,4,8,11
    ASD7    5
    ASD8    2,5
;

data want(keep=code new);
set a;
do i=1 to 99 while (scan(type,i) ne ' ');
new=input(scan(type,i),2.);
output;
end;
run;

proc print;run;

Re: How to transfer this dataset?

art297 — Fri, 03 Aug 2012 15:42:57 GMT

Basically, the same suggestion as Linlin, but I'd make i a counter rather than a loop. i.e.:

data b (keep=code type);

set a (rename=(type=type_in));

i=1;

do while (scan(type_in,i,",") ne "");

type=input(scan(type_in,i,","),2.);

output;

i+1;

end;

run;

Re: How to transfer this dataset?

Haikuo — Fri, 03 Aug 2012 15:44:41 GMT

LinLin,

How about removing the rigid part of '99' and using 'by 1'?

data want(keep=code new);

set a;

do i=1 by 1 while (scan(type,i) ne ' ');

new=input(scan(type,i),2.);

output;

end;

run;

Haikuo

Re: How to transfer this dataset?

tish — Fri, 03 Aug 2012 15:52:28 GMT

LOL I'd loop it and go to the number of commas plus 1. I left in some commented code for the possibility that you want the value to be character, not numeric.

data B (keep=code value);

set A;

/* length value $ 2; */

do i = 1 to countc(type, ',')+1;

/* value = scan(type, i); */

value = input(scan(type, i), 2.0);

output;

end;

run;

Re: How to transfer this dataset?

Linlin — Fri, 03 Aug 2012 15:55:48 GMT

Thank you Haikuo! I will use it in the future.

Re: How to transfer this dataset?

rpg163 — Fri, 03 Aug 2012 16:11:30 GMT

Many Thanks!

Re: How to transfer this dataset?

rpg163 — Fri, 03 Aug 2012 16:11:46 GMT

Thank you!

Re: How to transfer this dataset?

rpg163 — Fri, 03 Aug 2012 16:12:11 GMT

Thank you!