topic Proc Report in SAS Procedures

Proc Report

robertrao — Wed, 17 Jul 2013 19:06:03 GMT

Hi,

I want to write Footnotes in the Proc Report

footnote1:Total number of discharges:22

footnote2:Discharges with headaches:5 etc etc

I will know the count only after running the code for the datasets.for example 22 is got i the log after running a piece of code

5 is got after running a piece of code..

Instead of manually entering the counts in Footnotes How can I get SAS to write automatically?????(USING SYMPUT?????)

Thank you

Ksharp — Thu, 18 Jul 2013 01:10:05 GMT

Yes. you should use a macro variable.

Cynthia_sas — Thu, 18 Jul 2013 02:29:34 GMT

Hi:

You CAN use Macro variables, but you do not necessarily need CALL SYMPUT. SQL will do it too.

cynthia

proc sql;

select distinct(sex), count(sex) into :cntgend1-:cntgend2, :tot1-:tot2

from sashelp.class

group by sex;

quit;

%put cntgend1=&cntgend1 tot1=&tot1;

%put cntgend2=&cntgend2 tot1=&tot2;

proc format;

value $gfmt 'F' = 'Females'

'M' = 'Males';

run;

ods html file='c:\temp\macvar.html';

proc report data=sashelp.class nowd;

title "The Report";

footnote "Total %sysfunc(putc(&cntgend1,$gfmt.)): &tot1";

footnote2 "Total %sysfunc(putc(&cntgend2,$gfmt.)): &tot2";

column age sex ('Average' height weight);

define age / group;

define sex / group;

define height / mean 'Height';

define weight / mean 'Weight';

run;

ods html close;