topic Re: How can I do this type of regression? in SAS Procedures

How can I do this type of regression?

RazzleBayker — Thu, 22 Nov 2012 21:05:08 GMT

I have several thousand observations. I want a code for a regression that would work like a moving average; i need a regression for obs 1 through 200, then a regression for obs 2 through 201, then 3 through 202, etc etc. Is this possible to do without making a seperate sample for each regression? Any idea what the coding would look like?

Thanks in advance.

Re: How can I do this type of regression?

art297 — Thu, 22 Nov 2012 21:25:30 GMT

Not sure if there is a more direct way, but you could always wrap the reg call in a macro. E.g., given sashelp.class which has 19 records, the following would run regressions on records 1 thru 5, then 2 thru 6, etc, thru 15 thru 19:

%macro repeatreg (number,lastset);

%do i=1 %to &lastset;

%let j=%eval(&i.+&number.);

proc reg data=sashelp.class (firstobs=&i obs=&j.);

model age=height weight;

run;

quit;

%end;

%mend repeatreg;

%repeatreg(5,15)

Re: How can I do this type of regression?

Reeza — Thu, 22 Nov 2012 21:44:44 GMT

use by groups after classifying your observations into groups, you can use proc format to help.

proc sort data=sashelp.class; by sex;

proc reg data=sashelp.class;

by sex;

model age=height weight;

run;

quit;

Re: How can I do this type of regression?

PGStats — Thu, 22 Nov 2012 21:55:43 GMT

Or use a view and POINT=

data rCars(keep=grp engineSize horsepower) / view=rCars;
do grp = 0 to nbCars-200;
     do j = 1 + grp to 200 + grp;
          set sashelp.cars nobs=nbCars point=j;
          output;
          end;
     end;
stop;
run;

proc reg data=rCars outest=eCars;
by grp;
model horsePower = enginesize;
run;

That way you don't create any new version of your dataset and you can collect all the results in a single dataset.

Re: How can I do this type of regression?

Reeza — Thu, 22 Nov 2012 22:42:33 GMT

You can tell the Canadians today....

Re: How can I do this type of regression?

art297 — Thu, 22 Nov 2012 22:48:18 GMT

I couldn't talk my wife into doing two thanksgivings this year. Anyone have a spare turkey leg?

P.S.: I like your solution

Re: How can I do this type of regression?

PGStats — Fri, 23 Nov 2012 01:51:42 GMT

You can also get rid of the random access (POINT=) and read the data only once, using arrays :

%let regSize=200;

data rCars(keep=grp engineSize horsepower) / view=rCars;
array es{&regSize} _temporary_;
array hp{&regSize} _temporary_;
set sashelp.cars;
st = 1 + mod(_n_-1, &regSize);
es{st} = engineSize;
hp{st} = horsePower;
if _n_ >= &regSize then do;
     grp = 1 + _n_ - &regSize;
     do i = st+1 to &regSize, 1 to st;
          engineSize = es{i};
          horsePower = hp{i};
          output;
          end;
     end;
run;

proc reg data=rCars outest=eCars;
by grp;
model horsePower = enginesize;
run;

Re: How can I do this type of regression?

Ksharp — Fri, 23 Nov 2012 02:07:53 GMT

ArthurT,

Actually I like your solution more than PG's . PG's code will generated lots of obs when it is a big data.

Ksharp

Re: How can I do this type of regression?

PGStats — Fri, 23 Nov 2012 02:13:31 GMT

A view doesn't generate any data. At least, it doesn't have to. - PG

Re: How can I do this type of regression?

Linlin — Fri, 23 Nov 2012 16:04:49 GMT

Hi Art,

Sorry, no spare turkey leg from me. You can have something else, enjoy it! - Linlin

Re: How can I do this type of regression?

art297 — Fri, 23 Nov 2012 16:12:00 GMT

How long before the mead is ready for consumption?

Re: How can I do this type of regression?

Linlin — Fri, 23 Nov 2012 16:19:50 GMT

This is wine from grapes with a little bit honey added. I am going to make mead(only use honey and water) in December.

Re: How can I do this type of regression?

1zmm — Fri, 23 Nov 2012 18:34:14 GMT

Search using Google for "rolling window regression" in SAS:

http://www.sas-programming.com/2011/08/rolling-analysis-of-time-series.html.

http://www.nesug.org/proceedings/nesug07/sa/sa04.pdf

Re: How can I do this type of regression?

Ksharp — Mon, 26 Nov 2012 05:24:06 GMT

PG,

Yeah, But when you implement PROC REG ,it will produce lots of obs in a dataset.

Re: How can I do this type of regression?

PGStats — Mon, 26 Nov 2012 16:42:12 GMT

There won"t be much data produced unless you include an OUTPUT statement (to get predicted values or residuals). The OUTEST=eCars option produces a single observation per regression. You can also request the NOPRINT option to suppress printed output. - PG

Re: How can I do this type of regression?

Ksharp — Tue, 27 Nov 2012 02:37:34 GMT

Hi. PG,

I do not think so.

when you implement REG , data=rCars will generate a concrete dataset even you cann't see it .

View only contains the sas code you wrote before, when sas use reg model ,it will also need a real dataset to feed REG. View can't do it , I guess so. Did you make a experiment for it ?

Ksharp

Re: How can I do this type of regression?

PGStats — Tue, 27 Nov 2012 16:57:57 GMT

I tested both solutions that I proposed. I can't tell if a hidden dataset is created by executing the view or if some other kind of interprocess communication is used. It might depend on its size. - PG

Re: How can I do this type of regression?

Ksharp — Wed, 28 Nov 2012 03:14:54 GMT

Hi, PG

I believe a concrete dataset in somewhere, VIEW only contains the sas code ,you can't feed it into REG .

when you execute PROC REG ,sas will generate a dataset to feed it . You can't walk around it by using View.

Regards.

Ksharp

Re: How can I do this type of regression?

PGStats — Tue, 11 Dec 2012 16:13:18 GMT

Please check section Performance Considerations in

http://support.sas.com/documentation/cdl/en/lrcon/65287/HTML/default/viewer.htm#n07vq6hmss6f67n1vhnnn5cw0chh.htm

It states that when only sequential access is required, no actual dataset is created when reading a data step view.