topic Re: SAS index function in SAS Procedures

SAS index function

abcd123 — Fri, 12 Jul 2013 20:10:18 GMT

Hello,

I have following codes:

data test;

input var $;

cards;

BACABBAD

;

data test;

set test;

position=index(var,"A");

run;

here, position=2, which is the position of first "A" in the string. Now, my question is: how can I get the position of third (or second, fourth, ...) "A" in the string?

Re: SAS index function

AhmedAl_Attar — Fri, 12 Jul 2013 21:00:38 GMT

I would recommend you look into Help Document for the FINDC function.

I think it would be more suitable to what you want to do.

Hope this helps,

Ahmed

Re: SAS index function

CTorres — Fri, 12 Jul 2013 21:01:39 GMT

Try this:

data test;

input var $;

cards;

BACABBAD

AAAAAAAA

XXXXXXXX

XXAAXXAX

;

run;

data test(keep=var msg);

set test;

length msg $ 80;

n=count(var,'A');

if n=0 then msg="Any letter 'A' found";

else do;

msg="Letter 'A' found in positions ";

var2=var;

do i=1 to n;

p=index(var2,'A');

msg=strip(msg) || put(p,2.);

substr(var2,p,1)='*';

end;

run;

CTorres

Re: SAS index function

Astounding — Fri, 12 Jul 2013 21:07:35 GMT

Your best bet is to learn the PRX functions, such as PRXPOSN. If you had to do this the "old school" way, here is an approach to find the 3rd occurrence:

data want;

set have;

position_n=3;

string_to_search = value || ' ';

position=0;

do _n_=1 to position_n;

found_location = index(string_to_search, "A");

if found_location then do;

position + found_location;

string_to_search = substr(string_to_search, found_location + 1);

end;

else do;

position = 0;

_n_ = position_n;

end;

run;

There can be (solvable) complications when the string you are searching for is a blank, rather than "A". The code is untested, so you may need to tweak it mildly.

Good luck.

Re: SAS index function

abcd123 — Sat, 13 Jul 2013 02:22:02 GMT

Thank you all. I heard about rgx in sas but never tried; I will try the rgx.

Thanks.

Re: SAS index function

Scott_Mitchell — Sat, 13 Jul 2013 09:36:50 GMT

DATA HAVE;

ATTRIB VAR LENGTH = $8.;

INPUT VAR $;

DATALINES;

BACABADA

AAAAAAAA

;

RUN;

%LET DIM = ;

%LET DSID = %SYSFUNC(OPEN(HAVE,I));

%LET DIM = %SYSFUNC(VARLEN(&DSID,%SYSFUNC(VARNUM(&DSID,VAR))));

%LET RC = %SYSFUNC(CLOSE(&DSID));

%PUT ********&DIM;

DATA WANT;

SET HAVE;

ATTRIB VAR1 LENGTH=$&DIM..;

ARRAY POS APOS1-APOS&DIM.;

DO I = 1 TO COUNT(VAR,"A");

IF I = 1 THEN DO;

POS{I} = INDEX(VAR,"A");

VAR1 = SUBSTR(VAR,INDEX(VAR,"A")+1);

END;

ELSE DO;

POS{I} = SUM(INDEX(VAR1,"A"),POS{I-1});

VAR1 = SUBSTR(VAR1,INDEX(VAR,"A")+1);

END;

DROP VAR1;

RUN;

Re: SAS index function

data_null__ — Sat, 13 Jul 2013 13:19:33 GMT

AhmedAl-Attar wrote:

I would recommend you look into Help Document for the FINDC function.

I think it would be more suitable to what you want to do.

Hope this helps,

Ahmed

This is a good answer but requires RTM and no one does that anymore.

data test;
   input var $;
   retain target 'A'; 
   do s = 1 by 0; 
      r = findc(var,target,s);
      if r eq 0 and s=1 then output; 
      if r eq 0 then leave;
      output; 
      s = r+1; 
      end; 
   drop s;
   cards; 
BACABBAD
A
BBBB
AAAAA
;;;;
   run; 

Re: SAS index function

slchen — Sat, 13 Jul 2013 15:01:39 GMT

data test;

input var $;

cards;

BACABBAD

;

run;

data A_at;

set test;

do until (index(var,'A')=0);

position=index(var,"A");

var=substr(var,position+1);

A_at+position;

output;

end;

drop position;

run;

Re: SAS index function

Tom — Sat, 13 Jul 2013 16:30:59 GMT

You can use the FIND() function. It will let you specify a starting position for the search. If you want to search for any single character from a list of characters then use the FINDC() function.

Example:

data test;

input var $;

put var / @ ;

position=find(var,"A");

do while (position);

put @position 'X' @ ;

position=find(var,"A",position+1);

end;

cards;

BACABBAD

;

.BACABBAD

. X X X

Re: SAS index function

abcd123 — Sat, 13 Jul 2013 22:31:41 GMT

Thank you all for great help.