topic Re: how to use variables from another data step? in SAS Procedures

how to use variables from another data step?

littlestone — Tue, 24 May 2011 19:13:35 GMT

dear all,
suppose I have following codes:

data test; /*data step 1*/
input var1-var6;
cards;
1 1 1 1 1 1
;
run;

data _null_; /*data step 2*/
dsid = open ('work.test');
NumOfVar = attrn (dsid,'NVAR');
run;

What I want to do is: I want to use the variable NumOfVar created by data step 2 , and use it in data step 3, as following:

data test2; /*data step 3*/
array NewVar(NumOfVar);
do i=1 to NumOfVar;
newvar(i)=i;
end;
run;

Is there a way to make it possible? thanks. Message was edited by: littlestone

Re: how to use variables from another data step?

littlestone — Tue, 24 May 2011 20:55:22 GMT

any suggestion?

or did I violate any SAS coding rules in my codes?

please...

Re: how to use variables from another data step?

Peter_C — Tue, 24 May 2011 20:56:42 GMT

pass the value as a macro variable

data _null_ /*data step 2*/
dsid = open ('work.test');
NumOfVar = attrn (dsid,'NVAR');
call symputx( 'numOfvar', numofVar ); * push the value into macro var ;
run;

option symbolgen ;
data test2; /*data step 3*/
array NewVar(&NumOfVar) ; * referring to the value ;
do i=1 to &NumOfVar;
newvar(i)=i;
end;
run;

Re: how to use variables from another data step?

SPR — Tue, 24 May 2011 20:59:57 GMT

Hello Littlestone,

I made some changes in your code:
[pre]
data _null_; /*data step 2*/
dsid = open ('work.testl');
NumOfVar = attrn (dsid,'NVAR');
call SYMPUTX('NumOfVar',NumOfVar);
run;
data test2; /*data step 3*/
array NewVar{&NumOfVar} newvar1-newvar&NumOfVar;
do i=1 to &NumOfVar;
newvar[i]=i;
end;
run;
[/pre]
Sincerely,
SPR

Message was edited by: SPR Message was edited by: SPR

Re: how to use variables from another data step?

littlestone — Wed, 25 May 2011 02:42:38 GMT

I am so sorry for the late response ( my boss wants me to do sth else ...).

I tested both codes; unfortunately, neithe go through.

Here is one code I tested:

data test; /*data step 1*/
input var1-var6;
cards;
1 1 1 1 1 1
;
run;

data _null_; /*data step 2*/
dsid = open ('work.testl');
NumOfVar = attrn (dsid,'NVAR');
call SYMPUTX('NumOfVar',NumOfVar);
run;

data test2; /*data step 3*/
array NewVar{&NumOfVar} newvar1-newvar&NumOfVar;
do i=1 to &NumOfVar;
newvar=i;
end;
run;

Can someone tell me what is wrong with the code?

Re: how to use variables from another data step?

Peter_C — Wed, 25 May 2011 05:53:54 GMT

you create work.test but then try to open work.test1
Possibly you get a message like[pre]623 dsid = open ('work.testl');
624 NumOfVar = attrn (dsid,'NVAR');

NOTE: Argument 1 to function ATTRN at line 624 column 14 is invalid.
dsid=0 NumOfVar=. _ERROR_=1 _N_=1[/pre]Notice the value of DSID=0
If you had been able to open TEST1 then DSID would have had a value greater than zero.
try again with [pre] dsid = open ('work.test');

Re: how to use variables from another data step?

SPR — Wed, 25 May 2011 13:26:11 GMT

Hello Littlestone,

Your code contains an error:

instead of dsid = open ('work.TESTL');
should be dsid = open ('work.TEST');

Sincerely,
SPR

Re: how to use variables from another data step?

littlestone — Wed, 25 May 2011 15:18:51 GMT

Thank you so much for helping me.
I did not realize I made such an obvious mistake. I truly apologize for that.

I ran the code again and it works!
Here is the working codes:

data test; /*data step 1*/
input var1-var6;
cards;
1 1 1 1 1 1
;
run;

data _null_; /*data step 2*/
dsid = open ('work.test');
NumOfVar = attrn (dsid,'NVAR');
call SYMPUTX('NumOfVar',NumOfVar);
run;

data test2; /*data step 3*/
array NewVar(&NumOfVar) newvar1-newvar&NumOfVar;
do i=1 to &NumOfVar;
newvar(i)=i;
end;
run;

Thank you all very much for helping me out!