topic Re: Output based on the value of next record in SAS Procedures

Output based on the value of next record

bncoxuk — Tue, 14 Jun 2011 14:14:24 GMT

The decision to retain the current record is based on the value of a variable (Age) in the next record. If the next record has Age>30, then the current whole record should be kept. Is there any statement to deal with this?

Policy Location Year Age
142 12 1978 32
143 05 1980 31
144 17 1990 20

So in the output, the first record should be kept, and the second one deleted.

Re: Output based on the value of next record

ArtC — Wed, 15 Jun 2011 02:25:19 GMT

Try this. Obviously you never want the last observation.
[pre]data ages;
input Policy Location Year Age;
datalines;
142 12 1978 32
143 05 1980 31
144 17 1990 20
145 05 1992 31
146 17 1995 39
run;

data usenext;
set ages(firstobs=2 keep=age rename=(age=nextage));
set ages;
if nextage>30;
run;
proc print data=usenext;
run;
[/pre]

Re: Output based on the value of next record

Kevin_Graduate — Wed, 15 Jun 2011 09:06:05 GMT

Very good idea. Great, ArtC.

Re: Output based on the value of next record

Ksharp — Thu, 16 Jun 2011 04:10:27 GMT

Art.C 's code remind me the skill introduced by Peter.C

[pre]
data ages;
input Policy Location Year Age;
datalines;
142 12 1978 32
143 05 1980 31
144 17 1990 20
145 05 1992 31
146 17 1995 39
;
run;
data want(drop=_age);
merge ages ages(keep=age rename=(age=_age) firstobs=2);
if _age gt 30 ;
run;
[/pre]

Ksharp

Re: Output based on the value of next record

Kevin_Graduate — Thu, 16 Jun 2011 09:22:26 GMT

Marvelous ideas of you two.

Does Peter C. write any SAS books for me to learn these great ideas?

Re: Output based on the value of next record

Ksharp — Fri, 17 Jun 2011 01:34:45 GMT

Hi.
I called it Merge Skill .

Where are you ,Peter.C?
Someone want to talk to you.
Maybe you can introduce us some valueable documentations. 🙂

Ksharp Message was edited by: Ksharp