topic Find Character values in variable in SAS Procedures

Find Character values in variable

Jackie_Stanbank — Fri, 25 Nov 2011 12:14:47 GMT

I have a variable with values containing numeric as well as alphabetic characters.(eg. 1675ag157). I want to put the observations that contains alphas in a seperate dataset. Is there a formula that i can use to identify these records other than a lengthy if statement?

Find Character values in variable

andreas_lds — Fri, 25 Nov 2011 12:34:53 GMT

You can use the anyalpha-function:

...

if anyalpha(variable) then output alphas;

else output numerics;

...

Find Character values in variable

sas_Forum — Mon, 28 Nov 2011 11:08:26 GMT

data l;
input x $;
cards;
rt56y
polio
run;

data l2(drop=c) l3(drop=c);
set l;
c=anydigit(x);
if c=0 then output l2;
else output l3;
run;
proc print data=l2;
run;

Find Character values in variable

GreggB — Tue, 29 Nov 2011 20:06:53 GMT

did any of these replies answer your question?

Find Character values in variable

FriedEgg — Tue, 29 Nov 2011 22:20:51 GMT

*solution using regular expression;

data digits alphas;

input key $;

if prxmatch('/[a-zA-Z]+/',key) then output alphas; else output digits;

cards;

1675ag157

ag09912

simpton

123476

32246

12345h

;

run;

Find Character values in variable

art297 — Wed, 30 Nov 2011 00:13:20 GMT

Matt, Just FWIW, Andreas' proposed anyalpha solution ran twice as fast as using a regular expression. The code I ran, on 100,000 replications of your example data, was:

data digits alphas;

set have;

if prxmatch('/[a-zA-Z]+/',key) then output alphas;

else output digits;

run;

data digits alphas;

set have;

if anyalpha(key) then output alphas;

else output digits;

run;

Find Character values in variable

FriedEgg — Wed, 30 Nov 2011 00:22:21 GMT

Yes, in my opinion SAS does not implement regular expressions efficiently, in most cases a native function will outperform. The benefit generally comes from more specific strings and cases that fall outside what the index and find functions can do (and the anyalpha/similar functions).

Find Character values in variable

Ksharp — Wed, 30 Nov 2011 02:35:03 GMT

FriedEgg

You can use 'o' modifier to prevent SAS parse Perl Regular Expression at every data step loop.

That will be fast a lot.

if prxmatch('/[a-zA-Z]+/o',key) then output alphas; else output digits;

Ksharp

Find Character values in variable

FriedEgg — Wed, 30 Nov 2011 15:47:39 GMT

Thanks Ksharp, I did not know that hint. Another option is to use prxparse first and then retain the id. This does save a substantial amount of time when processing, however I still find it typically to be less efficient.