topic PROC Means and the mode. in SAS Procedures

PROC Means and the mode.

GemmaR — Fri, 10 Feb 2012 12:23:53 GMT

Hi Guys,

I’m trying to use the PROC MEANS to calculate the mode and output it to an output dataset but it seems that if the classficiation variable is unique then it returns a missing value.

Two questions, is that correct? And is there anyway around this?

Little bit of code attached to demonstrate.

Many thanks in advance for your help!

PROC Means and the mode.

art297 — Fri, 10 Feb 2012 13:26:36 GMT

Not a perfect alternative, but the following will work for all cases except D where there aren't any non-unique replications:

proc univariate data=test modes;

class char;

var num;

output out=test2 mode=mode;

run;

PROC Means and the mode.

GemmaR — Fri, 10 Feb 2012 17:10:28 GMT

Thanks Art, that's a solution I have come up with in the meantime but it's taking between a quarter and about a third longer to execute so I was hoping that I was missing something really simple in the proc means.

But at least I can say I have tried to find out when my customers start chuntering!

Thanks again.

PROC Means and the mode.

data_null__ — Fri, 10 Feb 2012 18:06:46 GMT

if n=1 mode=sum or mean or min or max .

PROC Means and the mode.

art297 — Fri, 10 Feb 2012 22:02:40 GMT

DN: Please explain your comment.

Re: PROC Means and the mode.

data_null__ — Fri, 10 Feb 2012 22:20:17 GMT

The only differenc appears to be when N=1 so you can just make the MODE equal to the value. (MIN SUM MEAN MAX)

data test;
input char $ num;
datalines;
A 9
B 8
B 8
B 7
B 7
C 8
D 6
D 5
E 5
E 5
;
run;
proc summary data=test nway;
      class char;
      var num;
      output out=test2 mode=mode n=n min=min;
   run;
data test2;
   set test2;
   if n eq 1 then mode=min;
   run;
proc print;
   run;
proc univariate data=test noprint;
   class char;
   var num;
   output out=test3 mode=mode n=n min=min;
   run;
Proc print;
   run;
Proc compare base=test2 compare=test3;
   run;

Re: PROC Means and the mode.

art297 — Fri, 10 Feb 2012 22:23:38 GMT

Thanks! I was wondering what you were referring to.

There is another problem, though, in that proc means and summary don't output multiple modes when they exist. They simply select (as I recall) the lowest value.

Re: PROC Means and the mode.

data_null__ — Fri, 10 Feb 2012 22:57:23 GMT

To getmulti-modal output you need use the ODS OUTPUT data set from UNIVARIATE. I can't recall the name.

I don't know when the mode is an interesting statistic. I can't recall every putting it into a phama data summary.

Re: PROC Means and the mode.

art297 — Fri, 10 Feb 2012 23:01:19 GMT

It is definitely of interest if one is trying to use stats to analyze their data, as a multi-modal distribution could easily violate the statistic's assumptions. Of course, I am not a statistician

Re: PROC Means and the mode.

data_null__ — Fri, 10 Feb 2012 23:09:30 GMT

Multi what?

Re: PROC Means and the mode.

art297 — Fri, 10 Feb 2012 23:22:30 GMT

OK, besides not being a programmer or statistician, I can't type either! I changed multi-nomal to multi-modal in my response.

Re: PROC Means and the mode.

Ksharp — Mon, 13 Feb 2012 03:18:18 GMT

I think SAS is right.

mode is the number which has the biggest frequence. So If you only have one value or

several value has the same frequence, SAS don't know which value is the mode.

data test;
input char $ num;
datalines;
A 9
B 8
B 8
B 7
B 7
C 8
D 6
D 5
E 5
E 5
;
run;
proc freq data=test noprint;
table char*num/out=freq nopercent nocum;
run;
proc sort data=freq;by char descending count;run;
data want(keep=char num);
 set freq;
 by char;
 if first.char;
run;

Ksharp

Re: PROC Means and the mode.

art297 — Mon, 13 Feb 2012 03:42:29 GMT

Ksharp, I don't understand what you are saying. If there is an N-way tie for the most frequent response, all N values involved in the tie constitute the modes of the distribution.

Re: PROC Means and the mode.

Ksharp — Mon, 13 Feb 2012 09:49:30 GMT

Ou............... My bad .

data test;
input char $ num;
datalines;
A 9
B 9
B 8
B 7
B 7
C 8
D 6
D 5
E 5
E 5
;
run;
proc freq data=test noprint;
table char*num/out=freq nopercent nocum;
run;
proc sort data=freq;by char descending count;run; 
data want(keep=char num);
 set freq;
 by char count notsorted;
 retain found;
 if first.char then found=0;
 if not found then output;
 if last.count then found=1;
run;

Ksharp