topic How to convert all numeric variables into characters and concatenate the values in SAS Procedures

How to convert all numeric variables into characters and concatenate the values

bncoxuk — Fri, 18 Nov 2011 10:19:26 GMT

I have a dataset with some unknow number of numeric variables (>10) and character variables (>20).

The question is how to convert all the numeric values into character values, and then contatenate these values into a single string.

Thanks very much.

How to convert all numeric variables into characters and concatenate the values

LinusH — Fri, 18 Nov 2011 11:20:05 GMT

You could put all the variables into an array using the _numeric_ key-word.

Concatenation can you do in a do loop using the dim() function.

/Linus

Re: How to convert all numeric variables into characters and concatenate the values

Linlin — Fri, 18 Nov 2011 13:42:11 GMT

data have(drop=i);

do i=10 to 11;

n1=i;

n2=i+8;

n3=i+5;

n4=i+1;

n5=2*i;

output;

end;

run;

data want;

length new $ 200;

set have;

array _num(*) _numeric_;

new=catt(of _num(*));

run;

How to convert all numeric variables into characters and concatenate the values

art297 — Fri, 18 Nov 2011 13:48:32 GMT

data have;

do i=10 to 11;

n1=i;

n2=i+8;

n3=i+5;

n4=i+1;

n5=2*i;

output;

end;

run;

data want;

set have;

array nums(*) _numeric_;

newv=catx(' ',of nums(*));

run;

Re: How to convert all numeric variables into characters and concatenate the values

Howles — Fri, 18 Nov 2011 14:04:43 GMT

The ARRAY isn't necessary. Instead:

length newv $ 200 ;

newv=catx(' ',of _numeric_) ;

art297 wrote:
data have;
  do i=10 to 11;
   n1=i;
   n2=i+8;
   n3=i+5;
   n4=i+1;
   n5=2*i;
    output;
  end;
run;
data want;
  set have;
  array nums(*) _numeric_;
  newv=catx(' ',of nums(*));
run;