topic Re: Resetting counter on condition in SAS Procedures

Resetting counter on condition

akberali67 — Fri, 30 Mar 2012 13:28:45 GMT

Hi,

What can I do to reset the counter on a given condition.

Example Data;

Variable1

usually you would use _N_ to sequence but how do I get this output

a 1

b 2

c 3

N 4

q 1

r 2

a 3

w 4

e 5

N 6

How do I get it to reset. Maybe I do not understand what _N_ denotes properly. Please help. Thanks in advance.

-Akber.

Resetting counter on condition

Linlin — Fri, 30 Mar 2012 13:39:11 GMT

how about:

data have;

input var1$;

cards;

;

data temp;

set have;

retain count;

if lag(var1)='N' then count=1;

else count+1;

run;

proc print;run;

Resetting counter on condition

Tom — Fri, 30 Mar 2012 13:43:52 GMT

Another method is to reset the counter on the record that marks the end of the group. But do it AFTER writing the current count to the output dataset.

data want;

set have;

count+1;

output;

if var1='N' then count=0;

run;

Resetting counter on condition

Haikuo — Fri, 30 Mar 2012 14:04:04 GMT

Another option is DOW,

data want;

do count=1 by 1 until (var1='N');

set have;

output;

end;

run;

Re: Resetting counter on condition

MikeZdeb — Fri, 30 Mar 2012 16:39:25 GMT

hi ... another way to reset the COUNT for each new group ...

data have;

set have;

count + (-(lag(var1) eq 'N')*count) + 1;

run;

Re: Resetting counter on condition

Linlin — Fri, 30 Mar 2012 17:15:32 GMT

Hi Mike,

I will go to the BASUG Q1 meeting on 4/17/2012 in Boston. Looking forward to meeting you there.

Thanks,

Linlin

Re: Resetting counter on condition

akberali67 — Fri, 30 Mar 2012 19:03:53 GMT

This does work but it is very inefficient. It takes hours to run on even a small dataset. Probably because it assigns the values manually.

Re: Resetting counter on condition

Ksharp — Sat, 31 Mar 2012 03:11:42 GMT

data have;
input var1 $;
cards;
a
b
c
N
q
r
a
w
e
N
;
run;
data have;
 set have;
 if lag(var1) eq 'N' then count=0;
 count+1;
run;

Ksharp