topic Re: using first. = . repedetively in SAS Procedures

using first. = . repedetively

podarum — Fri, 03 Feb 2012 21:02:36 GMT

I have 3 first. criteria to use, but I must use ot on 14 different variables... is there a easy way to do this

if first.YEAR then price_GR=.;

if first.Type then price_GR=.;

if first.Store then price_GR=.;

I have 14 different price_GR=.; (eg. UN_GR, GDP_GR, etc.)

Cant have 14 series of the first.YEAR, first.Type and first.Store .. Is there a easy way to make them repedetive rather than type each out? thanks

using first. = . repedetively

art297 — Fri, 03 Feb 2012 21:08:51 GMT

I'm not sure what you are trying to do. You can always specify them as:

if first.YEAR then do;

price_GR=.;

etc.

end;

if first.Type then do;

etc.

end;

etc.

You could also load your data into an array and, rather than have 14 statements, just refer to the variables in the array.

Re: using first. = . repedetively

udo_sas — Fri, 03 Feb 2012 21:15:21 GMT

Not sure if this is what you are looking for. Regards, Udo

proc sort data=sashelp.class out=have;

by sex age;

run;

data want;

set have;

if first.sex then call missing(sex,age,height,weight);

if first.age then call missing(sex,age,height,weight);

by sex age;

run;

Re: using first. = . repedetively

podarum — Fri, 03 Feb 2012 21:20:01 GMT

Let me try to explain it better:

Is there better way to write this?

if first.YEAR then price_GR=.;

if first.Type then price_GR=.;

if first.Store then price_GR=.;

if first.YEAR then UN_GR=.;

if first.Type then UN_GR=.;

if first.Store then UN_GR=.;

if first.YEAR then GDP_GR=.;

if first.Type then GDP_GR=.;

if first.Store then GDP_GR=.;

and so on 14 times with 14 different VARS_GR.... Thanks

Re: using first. = . repedetively

art297 — Fri, 03 Feb 2012 21:22:59 GMT

Do those variables already exist and you just want them reset to missing?

Re: using first. = . repedetively

podarum — Fri, 03 Feb 2012 21:24:35 GMT

yes

Re: using first. = . repedetively

art297 — Fri, 03 Feb 2012 21:26:54 GMT

Here is an example of how you could do it for, say, all numeric variables:

proc sort data=sashelp.class out=test;

by age;

run;

data want;

set test;

array vars _numeric_;

by age;

if first.age then do over vars;

call missing(vars);

end;

run;

Re: using first. = . repedetively

Howles — Fri, 03 Feb 2012 23:00:37 GMT

by year type store ;

if first.store then call missing (UN_GR, GDP_GR, etc) ;

Re: using first. = . repedetively

Tom — Sat, 04 Feb 2012 00:01:17 GMT

As Howles has said already you do not need to test all of the higher level variables in the sort order. If it the first for higher level term it also the first for the lower level term, by the definition of how FIRST. is calculated. So it you just reset on the first. for the lowest level term it will also reset at the first for all of the higher level terms.

To reset a number of variables to missing use the call missing statement.

Re: using first. = . repedetively

Patrick — Sat, 04 Feb 2012 03:28:26 GMT

@ART

DO OVER?!

You definitely started with SAS some years ago. I believe DO OVER was already marked as "obsolete" in SAS V6 :smileylaugh:

In modern SAS you could write it with no explicit loop at all:

call missing(of _numeric_);

Re: using first. = . repedetively

art297 — Sat, 04 Feb 2012 03:44:00 GMT

Patrick,

Yes, I started with SAS a long time ago. In fact, before it became a company!

However, I still like using do over and don't know why they stopped including it in the documentation.

Yes, in this case, your suggestion is all that would be needed. But not quite so easy for other assignments. Unfortunately, they never included a similar call assign (e.g., call (assign,3, of _numeric_);