topic Re: Automatic Directory Creation - Windows in SAS Procedures

Automatic Directory Creation - Windows

vomer — Tue, 31 Jan 2012 15:48:27 GMT

I run some sas queries on a monthly basis and they export data to specific folders. Problem is I have to manually make these folders before I run the code so SAS wont error out.

Is there any way to automate this?

My folders have to be named in this fashion:

number of the Month - Name of the Month Year (12 - Dec 2011). I would also like to create a subfolder called Excel.

Also is there any way the month and number is populated automatically...so when I run this in January it changes to (1 - Jan 2012)?

Please provide the codes needed if possible...I am very new to SAS. Thanks!

Automatic Directory Creation - Windows

Doc_Duke — Tue, 31 Jan 2012 16:32:27 GMT

You could use the "X" command to shell out to Windows to create it.

For instance, if you had a macro variable with the name of the directory, it might look something like

%LET yrmo=12-Dec2011;

x "mkdir c:\mypath\&yrmo";

x "mkdir c:\mypath\&yrmo\excel";

Doc Muhlbaier

Duke

Re: Automatic Directory Creation - Windows

Haikuo — Tue, 31 Jan 2012 16:43:26 GMT

Assume you have access to C:\, and you want to use current date to name the folder:

data _null_;

mc=catx('-',month(today()),put(today(),monyy7.));

call symput('d',cats('md c:\',mc,'\excel\'));

run;

x "&d";

Please note: TODAY() helps to extract today's date. It also seems to me that dos command "md" does not support blank, so you will end up with no blank between mmm and yyyy. You can also add:

options noxwait;

at the beginning of the code to avoid manually get out of dos window.

Kindly Regards,

Haikuo

Re: Automatic Directory Creation - Windows

vomer — Tue, 31 Jan 2012 16:53:49 GMT

I am not looking for the folder name to be the current date. I just want it to be the month number (jan is 1, Feb is 2 etc.), month abbreviation and Year (01 - Jan - 2012)

Also, I want to make these on a network drive not the local drive... how would I go about that?

Re: Automatic Directory Creation - Windows

Haikuo — Tue, 31 Jan 2012 17:02:28 GMT

If you have tried my code above, it does exactly what you want. MONTH() to extract month info from TODAY().

It does not make a difference whether you are making folders locally or on network drive, as long as you have write access and it has been mapped correctly.

Regards,

Haikuo

Re: Automatic Directory Creation - Windows

vomer — Tue, 31 Jan 2012 17:20:22 GMT

Thanks Haikuo. I have one last question:

My directory is named in this fashion:

C:\AB&C\Reports & Tests\Folder

Your query seems to get stuck becuse of the "&" in my directory name...I unfortunately cannot rename it...how can I made the code work with this path?

Re: Automatic Directory Creation - Windows

Haikuo — Tue, 31 Jan 2012 17:40:33 GMT

Try this one:

data _null_;

mc=catx('-',month(today()),put(today(),monyy7.));

call symput('d',cats('md %nrbquote("c:\AB%nrbquote(&)C\Reports & Tests\")',mc,'\excel\'));

run;

x "&d";

Regards,

Haikuo

Edit: I am really a newbie in term of Macro language. So my code above would inevitably falls clumsy. Macro experts please recue!

Re: Automatic Directory Creation - Windows

polingjw — Tue, 31 Jan 2012 18:41:33 GMT

There is no need to use macro variables at all.

data _null_;

newdir=dcreate(catx('-', month(today()), put(today(), monyy7.)), 'C:\AB&C\Reports & Tests\');

run;

Re: Automatic Directory Creation - Windows

Haikuo — Tue, 31 Jan 2012 18:50:57 GMT

awesome! I did not know the existence of dcreate(). Thanks a lot!

Re: Automatic Directory Creation - Windows

Tom — Tue, 31 Jan 2012 21:59:57 GMT

Make sure to put the month with leading zero. Otherwise the directories will not sort properly in most browsing tools like Windows Explorer.

data _null_;

newdir=dcreate(catx('-', put(month(today()),z2.), put(today(), monyy7.)), 'C:\AB&C\Reports & Tests\');

run;

What I have been doing lately for date stamps in files or directory is using the YYMMDD format. That sorts properly and avoids confusion over which part is month and which is day.

For you report structure perhaps you want 2012 - 01 - January ? Or perhaps introduce a year folder? 2012\01 - January ?

Re: Automatic Directory Creation - Windows

vomer — Thu, 02 Feb 2012 19:59:09 GMT

This worked but I just have 1 small issue. When I run this I don't get a space between the month and the year... so it looks like : 02 - FEB2012

How should I modify it so it looks like : 02 - FEB 2012 (note space after month)

Also, is there any way to modify this code so it creates the previous month's folder?

Thanks.

Re: Automatic Directory Creation - Windows

Tom — Thu, 02 Feb 2012 20:04:25 GMT

Pull out the month and year separately. Use the MONNAME3 format to get first three characters of the month name.

data _null_;

newdir=dcreate(

catx('-'

, put(month(today()),z2.)

, put(month(today()), monname3.)||''||put(year(today()),4.)

)

, 'C:\AB&C\Reports & Tests\');

run;

Re: Automatic Directory Creation - Windows

art297 — Thu, 02 Feb 2012 20:11:09 GMT

Just change the '-' to ' - '. e.g.,

data _null_;

newdir=dcreate(catx(' - ', month(today()),

put(today(), monyy7.)),

'C:\AB&C\Reports & Tests\');

run;

Automatic Directory Creation - Windows

vomer — Thu, 02 Feb 2012 20:52:13 GMT

Tried the code and it created the space but now the month name is wrong... so it outputs : 02 - Jan - 2012

Another Question : How do I make this code create a folder for the previous month. So if I run this in Feburary it creates a folder named : 01 - Jan 2012

Many Thanks!!

Re: Automatic Directory Creation - Windows

vomer — Thu, 02 Feb 2012 21:00:15 GMT

Tried the code and it created the space but now the month name is wrong... so it outputs : 02 - Jan - 2012

Code Used:

data _null_;

newdir=dcreate(

catx(' - '

, put(month(today()),z2.)

, put(month(today()), monname3.)||''||put(year(today()),4.)

)

, 'U:\Software\');

run;

Another Question : How do I make this code create a folder for the previous month. So if I run this in Feburary it creates a folder named : 01 - Jan 2012

Many Thanks!!

Re: Automatic Directory Creation - Windows

Tom — Thu, 02 Feb 2012 21:12:23 GMT

Take out the second MONTH() function, MONNAME format applies to real date, not a month number. It was getting the month for 02JAN1960.

To figure out what date it was last month use the INTNX function.

Re: Automatic Directory Creation - Windows

vomer — Thu, 02 Feb 2012 21:21:04 GMT

Sorry I am a bit confused... taking it out caused an error...

Also where/how does the INTNX go? Could you please provide the code.. sorry I am very new to SAS.

Re: Automatic Directory Creation - Windows

Tom — Thu, 02 Feb 2012 22:09:40 GMT

This will get todays date. Get a date in the previous month. Build the directory names into variables. Then call the DCREATE() function to make the directories.

I put the parent directory into a variable so that I can use it two places without having to type it twice.

The PUT statement will let you see the directory names that it generated and the result of the DCREATE function.

data _null_;
  rootdir='U:\Software\';
  today=today();
  lastmonth=intnx('month',today,-1);
  dir1=catx(' ',put(month(lastmonth),z2.),'-',put(lastmonth,monname3.),year(lastmonth));
  dir2=catx(' ',put(month(today),z2.),'-',put(today,monname3.),year(today));
  newdir1=dcreate(dir1,rootdir);
  newdir2=dcreate(dir2,rootdir);
  put (rootdir dir1 newdir1 dir2 newdir2) (=/);
run;

Re: Automatic Directory Creation - Windows

vomer — Thu, 02 Feb 2012 23:56:23 GMT

Tom, that is amazing! I wil give this a try soon.

One final question (I promise) : After the directory (01 - Jan 2012) is made using the script your provided, is there any way I can also add a sub-directory under the newly created 01 - Jan 2012 folder?

I used an "x" command but it did not work and got stuck on the command line window.

Re: Automatic Directory Creation - Windows

Linlin — Fri, 03 Feb 2012 01:10:43 GMT

Hi,

I tried Tom's code. It works great! I was able to create a sub_directory "test" under the newly created "01 -jan 2012 "folder.

data _null_;

rootdir='c:\temp\';

today=today();

lastmonth=intnx('month',today,-1);

dir1=catx(' ',put(month(lastmonth),z2.),'-',put(lastmonth,monname3.),year(lastmonth));

dir2=catx(' ',put(month(today),z2.),'-',put(today,monname3.),year(today));

dir3='test'; /* Iadded */

newdir1=dcreate(dir1,rootdir);

newdir3=dcreate(dir3,newdir1); /* i added*/

newdir2=dcreate(dir2,rootdir);

put (rootdir dir1 newdir1 dir2 newdir2 dir3 newdir3) (=/);

run;

from log file:

rootdir=c:\temp\

dir1=01 - Jan 2012

newdir1=c:\temp\01 - Jan 2012

dir2=02 - Feb 2012

newdir2=c:\temp\02 - Feb 2012

dir3=test

newdir3=c:\temp\01 - Jan 2012\test

NOTE: DATA statement used (Total process time):

real time 0.03 seconds

cpu time 0.01 seconds

Message was edited by: Linlin