topic Re: How do I add two extra empty rows to my dataset? in SAS Procedures

How do I add two extra empty rows to my dataset?

Yennie — Tue, 27 Apr 2010 00:51:40 GMT

hi people,

I know SAS can do this through Edit mode by adding rows to the dataset manually. However, I am writting an automated script so I need to write out the sas code to add two extra empty rows to my dataset.

Hoping someone can give me some directions!

Cheers,
Yennie

Re: How do I add two extra empty rows to my dataset?

sbb — Tue, 27 Apr 2010 01:45:31 GMT

Empty rows -not sure why but you can assign a MISSING or BLANK value to all variables in the dataset and issue the OUTPUT; command. Possibly you might want to explain why you need this condition?

Scott Barry
SBBWorks, Inc.

Re: How do I add two extra empty rows to my dataset?

Cynthia_sas — Tue, 27 Apr 2010 15:05:04 GMT

Hi:
You will want to test for the end of the input file so that you only write out your two empty observations at the end. The END= option allows you to perform this test, as shown below.

cynthia
[pre]
data newclass;
** create variable to signal end of input file;
set sashelp.class end=nomore;

** output regular observations;
output;

** test for end of file. At end, NOMORE = 1;
if nomore then do;
** set variables to missing;
name = ' ';
sex = ' ';
height = .;
age = .;
weight = .;
** output 2 "empty" observations;
output;
output;
end;
run;

ods listing;
proc print data=newclass;
title '2 "empty" observations at end of file';
run;
[/pre]

Re: How do I add two extra empty rows to my dataset?

darrylovia — Tue, 27 Apr 2010 17:41:41 GMT

You could also use PROC SQL to do it

proc sql;

create table shoes as
select *
from sashelp.shoes;

insert into work.shoes
set Region="";
insert into work.shoes
set Region="";
quit;

In the SET clause just pick any variable that is in your data set

D

Re: How do I add two extra empty rows to my dataset?

Yennie — Tue, 27 Apr 2010 23:00:23 GMT

Hi Cynthia,

That really helps lots!

Many many thanks!! 🙂 🙂

Cheers,
Yennie

Re: How do I add two extra empty rows to my dataset?

Stewartli — Thu, 14 Dec 2017 06:02:55 GMT

Hi Cynthia,

I use SAS Enterprise Miner. SAS Enterprise Miner automatically added 2 empty rows to my dataset after imported dataset. I am not sure why it did that. Is there any method I can remove those rows? Thank you for your help.

Regards,

Stewart

Re: How do I add two extra empty rows to my dataset?

s_lassen — Thu, 14 Dec 2017 10:59:39 GMT

The fastest and easiest way to do it is probably to modify the dataset in place:

data x;
  if 0 then modify x; /* modify, but do not read any rows */
  output;
  output;
  stop;
run;

Re: How do I add two extra empty rows to my dataset?

Stewartli — Sat, 16 Dec 2017 00:25:13 GMT

Thank you Iassen. Appreciate it.