topic Re: Adding count above bar graph using Call BAR and proc iml in SAS/IML Software and Matrix Computations

Adding count above bar graph using Call BAR and proc iml

advmsj — Fri, 04 Sep 2020 12:17:59 GMT

Hi there, I am trying to add the counts above a bar graph, however, I am unfamiliar with the Call BAR function and cannot seem to find any answers online. I used the code provided below.

data SAS_Test;
input var1 var2 var3 var4;
datalines;
1	.	1	1
0	0	.	.
.	.	1	0
1	.	.	.
1	0	1	.
1	1	.	1
0	0	1	0
0	1	1	0
1	1	.	1
0	1	0	1
0	1	0	1
0	1	0	1
;
run;

proc means data=SAS_Test N NMISS;
run;

proc iml;
varNames = {var1 var2 var3 var4};

use SAS_Test;                      /* open data set */
read all var varNames into X;      /* create numeric data matrix, X */
close SAS_Test;

title "Counts of Rows That Contain Missing Values";
Count = countmiss(X,"row");       /* count missing values for each obs */
call Bar(Count);                  /* create bar chart */
run;

Thank you!

Re: Adding count above bar graph using Call BAR and proc iml

Ksharp — Fri, 04 Sep 2020 13:04:00 GMT

Check CALL BAR() option .

Calling @Rick_SAS

Re: Adding count above bar graph using Call BAR and proc iml

Rick_SAS — Fri, 04 Sep 2020 15:01:08 GMT

As mentioned in the doc, "The BAR subroutine displays a bar chart by calling the SGPLOT procedure. .... The BAR subroutine is not a comprehensive interface to the SGPLOT procedure. It is intended for creating simple bar charts."

The doc shows how to call the SGPLOT procedure to access any feature that PROC SGPLOT support. For example, you can modify the example in the doc to get this:

create Bar var {'Count'}; append; close Bar;  /* write to SAS data set  */
submit;
   proc sgplot data=Bar;                /* create the plot     */
      vbar Count / datalabel;
   run;
endsubmit;

Re: Adding count above bar graph using Call BAR and proc iml

advmsj — Fri, 04 Sep 2020 15:39:41 GMT

Thank you so much!