topic INPUT and PUT in IML in SAS/IML Software and Matrix Computations

INPUT and PUT in IML

Junyong — Fri, 27 Mar 2020 23:39:51 GMT

I convert, for example, "27mar2020"d to 202003 using PUT and INPUT as follows.

data y;
x="27mar2020"d;
y=input(put(x,yymmn6.),6.);
run;

Can one do something equivalent in IML? I don't want to use the 100*YEAR(X)+MONTH(X) approach because I use multiple formats such as yymmddn8. and year4.

proc iml;
x="27mar2020"d;
y=input(put(x,yymmn6.),6.);
/*y=100*year(x)+month(x); want to avoid*/
quit;

Thanks.

Re: INPUT and PUT in IML

Rick_SAS — Sat, 28 Mar 2020 00:19:47 GMT

Although the PUT and INPUT functions are valid in the DATA step, the PUTN, PUTC, INPUTN, and INPUTC functions are more widely supported. Since you want to use Numeric formats, use PUTN and INPUTN. (You chould use the C versions for Character formats.)

proc iml;
x="27mar2020"d;
t = putn(x,"yymmn6.");
y = inputn(t, "6.");
print t, y;

/* or next the function calls */
y=inputn(putn(x,"yymmn6."),"6.");
print y;

Re: INPUT and PUT in IML

Tom — Sat, 28 Mar 2020 01:02:38 GMT

I don't see how what format you have attached to the variable (year. vs yymmddn.) matter? The value it contains still needs to be a date value. Or did you mean that you want to create your different patterns of digit strings that you then convert into pseudo numbers?