topic Re: Using Data Set Inside Do Loops in SAS/IML Software and Matrix Computations

Using Data Set Inside Do Loops

Junyong — Sat, 09 Dec 2017 06:22:37 GMT

Hi, I want to ask if this is possible.

data DataSet;
	call streaminit(1);
	do Set=1 to 3;
		do Number=1 to 10;
			Variable=rand("normal");
			output;
		end;
	end;
run;

proc iml;
	do IMLSet=1 to 3;
		use DataSet(where=(Set=IMLSet));
			read all var{Variable};
		close DataSet;
	end;
quit;

In this case, DataSet contains Variable, which is indexed by both Set and Number. In IML, I intended to load DataSet Set by Set so used a loop with an IML variable IMLSet, but this does not work since the "where" only uses the variables in DataSet and it does not have IMLSet there. Alternatives are welcome.

Re: Using Data Set Inside Do Loops

Ksharp — Sat, 09 Dec 2017 09:46:29 GMT

data DataSet;
	call streaminit(1);
	do Set=1 to 3;
		do Number=1 to 10;
			Variable=rand("normal");
			output;
		end;
	end;
run;

proc iml;
use dataset;
read all var{set};
close;
level=unique(set);
do i=1 to ncol(level);
  use dataset;
  read all var _all_ into x where (set=(level[i]));
  print x;
  close;
end;
quit;

P.S. If you really want learn IML code, I really suggest you to read Rick's blog .You can find most answer of IML in it .

Re: Using Data Set Inside Do Loops

Rick_SAS — Sat, 09 Dec 2017 11:21:59 GMT

KSharp's solution is good. To read more about how to use the WHERE clause with dynamic values that change in a loop. See

"The WHERE clause in SAS/IML"

The only improvement I'd suggest to KSharp's code is to put the USE and CLOSE statements outside the DO loop. There is no need to open/close the data set multiple times. You can apply his solution to the OP's original attempt, as follows:

proc iml;
use DataSet;
	do IMLSet=1 to 3;
		read all var{Variable} where(Set=(IMLSet));
      print Variable;
	end;
close DataSet;
quit;

Re: Using Data Set Inside Do Loops

Ksharp — Sun, 10 Dec 2017 09:56:23 GMT

Yeah. I know what Rick mean. So here is the code revisited.

data DataSet;
	call streaminit(1);
	do Set=1 to 3;
		do Number=1 to 10;
			Variable=rand("normal");
			output;
		end;
	end;
run;

proc iml;
use dataset;

read all var{set};
level=unique(set);
do i=1 to ncol(level);
  read all var _all_ into x where (set=(level[i]));
  print x;
end;

close;
quit;