topic Re: Random combination of a subset of data set in SAS/IML Software and Matrix Computations

Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 02:45:11 GMT

Input id $ x y;

Datalines;

00-01 5 3

00-02 4 6

00-03 6 4

00-04 7 5

00-05 9 2

00-06 4 6

00-07 5 8

00-08 1 8

00-09 7 3

00-10 7 4

;

run;

Please, I want to generate Z random subset of data set CO chosen observation 4 at a time (10 chose 4). Let’s take Z in this case=7; I like to add additional column to identify each of the random subset—let call that variable REPS. I will appreciate a code that can run fast because the actual code might end up having up to 10,000 REPS. And number of variables can be larger.

I read Rick's blog and saw some examples, but I did not see an example where the combination involve actual data set. If it's not possible for more than a variable, I can do only the id (character variable) and merge back to the original data set.

Any help will be appreciated!

Thanks in Advance

Jack

Re: Random combination of a subset of data set

Reeza — Wed, 27 Apr 2016 03:07:07 GMT

Proc surveyselect will work.

Re: Random combination of a subset of data set

Reeza — Wed, 27 Apr 2016 03:20:38 GMT

Selection with or without replacement?

Re: Random combination of a subset of data set

PGStats — Wed, 27 Apr 2016 04:09:44 GMT

As @Reeza suggested:

data CO;
Input id $ x y;
Datalines;
00-01 5 3
00-02 4 6
00-03 6 4
00-04 7 5
00-05 9 2
00-06 4 6
00-07 5 8
00-08 1 8
00-09 7 3
00-10  7 4
;

proc surveyselect data=CO 
    method=srs /* Simple Random sampling without replacement */
    /*method=urs outhits*/ /* Simple Random sampling with replacement */
    reps=10 sampsize=4 
    out=COsamples seed=896358; 
run;

proc print data=COsamples noobs; run;

Re: Random combination of a subset of data set

Ksharp — Wed, 27 Apr 2016 09:07:31 GMT

Does PG's code make some sense ?

it IS possible for more than a variable for IML, But need some more code , and might not be friendly . You really want IML code ?

data have;
Input id $ x y;
Datalines;
00-01 5 3
00-02 4 6
00-03 6 4
00-04 7 5
00-05 9 2
00-06 4 6
00-07 5 8
00-08 1 8
00-09 7 3
00-10  7 4
;
run;
proc iml;
z=7;
k=4;

use have nobs nobs;
read all var{id x y};
close;
r=rancomb(nobs,k,z);



 new_id=j(k,1,blankstr(nleng(id)));
create want var{reps new_id new_x new_y};
do i=1 to nrow(r);
 idx=r[i,];
 reps=j(k,1,i);
 new_id=id[idx];
 new_x=x[idx];
 new_y=y[idx];
 append;
end;
close;

quit;

Re: Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 09:10:02 GMT

You guys are just incredible!!!

Many thanks. Let me digest this.

Re: Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 09:12:51 GMT

Incredible!!!

Let me evalute to this.

Re: Random combination of a subset of data set

Ksharp — Wed, 27 Apr 2016 09:28:25 GMT

This is vectorize operation . Could be very fast.

data have;
Input id $ x y;
Datalines;
00-01 5 3
00-02 4 6
00-03 6 4
00-04 7 5
00-05 9 2
00-06 4 6
00-07 5 8
00-08 1 8
00-09 7 3
00-10  7 4
;
run;
proc iml;
z=7;
k=4;

use have nobs nobs;
read all var{id x y};
close;
r=rancomb(nobs,k,z);


 idx=colvec(r);
 reps =colvec(row(r));
 new_id=id[idx];
 new_x=x[idx];
 new_y=y[idx];
create want var{reps new_id new_x new_y};
append;
close;

quit;

Re: Random combination of a subset of data set

Rick_SAS — Wed, 27 Apr 2016 13:18:39 GMT

This blog post explains to how to sample with or without replacement: "Four essential sampling methods in SAS". It links to other articles that provide details. It shows how to do the sampling by using PROC SURVEYSELECT and by using the SAMPLE function in SAS/IML.

Re: Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 16:43:07 GMT

It's basicacally to obtain a random subset of possible permutations of the data set. The reason is that in some settings, computer memory might limit the enumeration of all permutations. Therefor, a sufficiently large number of permutaion of the data set should suffice.

Thanks!

Re: Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 16:43:38 GMT

Thanks Rick!

Re: Random combination of a subset of data set

SWEETSAS — Wed, 27 Apr 2016 23:12:21 GMT

All the answers are essentially correct. Thank you all very very much.

Re: Random combination of a subset of data set

SWEETSAS — Thu, 28 Apr 2016 01:12:23 GMT

This is correct answer as well