topic Re: proc sgplot symbols option in Graphics Programming

proc sgplot symbols option

vraj1 — Tue, 17 Nov 2015 14:29:14 GMT

I am using proc sgplot and i need sybols in graph as for one treatment as 1 and other treatment as 2 and other treatment as P.

How can i do it using sgplot

Re: proc sgplot symbols option

DanH_sas — Tue, 17 Nov 2015 14:33:35 GMT

What version of SAS are you using?

Re: proc sgplot symbols option

vraj1 — Tue, 17 Nov 2015 14:34:19 GMT

SAS 9.4

Re: proc sgplot symbols option

DanH_sas — Tue, 17 Nov 2015 14:36:16 GMT

Are you scatter plots grouped or overlaid? It might be helpful to see a snippit of the SGPLOT code.

Re: proc sgplot symbols option

vraj1 — Tue, 17 Nov 2015 14:46:54 GMT

Attached a layout. in this instaed of circle i need '1' and instead of '*' i need as '2' and other one as 'P' may be.

Re: proc sgplot symbols option

DanH_sas — Tue, 17 Nov 2015 15:06:10 GMT

The reason I need to know if your SGPLOT code is using groups versus overlays is that it will make a difference in the solution. Is your plot statement using the GROUP option, or are you using three plot statements?

Re: proc sgplot symbols option

RW9 — Tue, 17 Nov 2015 15:09:21 GMT

In 9.4 there is an option symbol=, for which you can put a character in to display for each plot. See this:

http://blogs.sas.com/content/graphicallyspeaking/?s=symbol%3D

Note that blog is very useful for any graph questions.

Re: proc sgplot symbols option

DanH_sas — Tue, 17 Nov 2015 15:38:02 GMT

Here is a sample solution both the GROUPED and OVERLAID cases:

Overlaid:

proc sgplot data=sashelp.class;

symbolchar name=plot1 char='0031'x;

symbolchar name=plot2 char='0032'x;

scatter x=age y=height / markerattrs=(symbol=plot1 size=12pt);

scatter x=age y=height / markerattrs=(symbol=plot2 size=12pt);

run;

Grouped (two solutions):

ods graphics / attrpriority=none;

proc sgplot data=sashelp.class;

symbolchar name=plot1 char='0031'x;

symbolchar name=plot2 char='0032'x;

styleattrs datasymbols=(plot1 plot2);

scatter x=age y=height / group=sex markerattrs=(size=12pt);

run;

- OR -

data attrmap;

retain id "gender";

input value $ markersymbol $;

cards;

F plot1

M plot2

;

run;

proc sgplot data=sashelp.class dattrmap=attrmap;

symbolchar name=plot1 char='0031'x;

symbolchar name=plot2 char='0032'x;

scatter x=age y=height / group=sex markerattrs=(size=12pt) attrid=gender;

run;

Re: proc sgplot symbols option

vishnumethas — Tue, 24 Nov 2015 13:25:57 GMT

Produce a simple scatter plot 2. Label the axes 3. Label the data points 4. Group the data points using colors and symbols SESUG 2011 2 5. Use the %MODSTYLE macro to set non-default colors and symbols 6. Maintain the same colors and symbols across plots 7. Add a 45-degree line 8. Change the color of the 45-degree line 9. Label the legend for the colors and symbols 10. Position the legend 11. Adjust the height and width of the plot 12. Specify the output location.

Re: proc sgplot symbols option

vishnumethas — Tue, 24 Nov 2015 13:27:32 GMT

Produce a simple scatter plot 2. Label the axes 3. Label the data points 4. Group the data points using colors and symbols SESUG 2011 2 5. Use the %MODSTYLE macro to set non-default colors and symbols 6. Maintain the same colors and symbols across plots 7. Add a 45-degree line 8. Change the color of the 45-degree line 9. Label the legend for the colors and symbols 10. Position the legend 11. Adjust the height and width of the plot 12. Specify the output location