topic Re: PROC SGPLOT - LEGEND AND CURVELABEL TOGETHER in Graphics Programming

PROC SGPLOT - LEGEND AND CURVELABEL TOGETHER

P_S_ — Wed, 18 Mar 2015 20:06:05 GMT

Hi All,

I have sas 9.3. I am using SGPLOT and I have set of series plot and the legend for the lines and it works fine.

However I also need to add the label to each lines using curvelabel option so that the eye movement is reduced.

The problem is when I use curvelabel option the legend disappears.

Is there a way that I could have both in my plot?

Thank you for your help.

P.S.

Here is the code and the output as an example.

/*THIS GIVES ME THE LEGEND*/

proc sgplot data=sashelp.stocks(where=(date >= "01jan2000"d and stock = "IBM")) ;;

title "Stock Trend : IBM";

series x=date y=close /legendlabel="CCCC";

series x=date y=low /legendlabel="LLLL";

series x=date y=high /legendlabel="HHHH";

run;

Now I add the curvelabel option. It works but the LEGEND DISAPPEARS

proc sgplot data=sashelp.stocks(where=(date >= "01jan2000"d and stock = "IBM")) ;;

title "Stock Trend : IBM";

series x=date y=close /curvelabel='Close' curvelabelloc=inside curvelabelpos=max legendlabel="CCCC";

series x=date y=low /curvelabel='Low' curvelabelloc=inside curvelabelpos=max legendlabel="LLLL";

series x=date y=high /curvelabel='High' curvelabelloc=inside curvelabelpos=max legendlabel="HHHH";

legend ;

run;

Re: PROC SGPLOT - LEGEND AND CURVELABEL TOGETHER

ballardw — Wed, 18 Mar 2015 21:17:29 GMT

Does this do what you need:

proc sgplot data=sashelp.stocks(where=(date >= "01jan2000"d and stock = "IBM")) ;;

title "Stock Trend : IBM";

series x=date y=close /curvelabel='Close' curvelabelloc=inside curvelabelpos=max legendlabel="CCCC" name='a';

series x=date y=low /curvelabel='Low' curvelabelloc=inside curvelabelpos=max legendlabel="LLLL" name='b';

series x=date y=high /curvelabel='High' curvelabelloc=inside curvelabelpos=max legendlabel="HHHH" name='c';

keylegend 'a' 'b' 'c';

run;

Re: PROC SGPLOT - LEGEND AND CURVELABEL TOGETHER

DanH_sas — Wed, 18 Mar 2015 21:30:16 GMT

Ballardw is correct. By default, a curvelabel removes a plot from the auto legend because it is considered redundant information. Since the curve label was turned on for all three plot, the auto legend disappeared. However, you can override that behavior by creating your own legend, as in Ballardw's example.

Re: PROC SGPLOT - LEGEND AND CURVELABEL TOGETHER

P_S_ — Wed, 18 Mar 2015 22:16:01 GMT

Thanks Ballardw. It solves my problem.