topic Re: proc gchart annotate target for each bar in Graphics Programming

proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 09:34:38 GMT

Dear,

I have several countries on my x-axis.

On the y-axis there is the value.

I need to set a different target for each country.

For example: FRANCE: min 10: bonus: 30

GERMANY: min 20: bonus: 50

I have this now:

	proc gchart data=final_table;

	vbar country / sumvar=Value raxis=axis1
	nozero anno=anno
	DISCRETE ;

run;

Re: proc gchart annotate target for each bar

RW9 — Mon, 10 Aug 2015 09:48:07 GMT

Hi,

I answered a very similar question in this thread:

Simple answer - move to Graph Template Language. You can then have dynamic variables in the template and specify them at run time.

The other method is to generate the code.

Re: proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 10:45:11 GMT

RW9, thanks for your answer.

I have created a second graph with the graph template. Now it looks like my Barchart. In my dataset i have SL, and WL. Which are 2 reference lines, but they are different for each element.

Which should i do next?

proc template;

define statgraph barchart;

begingraph;

entrytitle "Average Mileage by Vehicle Type";

layout overlay;

barchart x=element y=Conc /

stat=sum orient=vertical ;

endlayout;

endgraph;

end;

proc sgrender data=txrf_final_table template=barchart;

run;

Re: proc gchart annotate target for each bar

RW9 — Mon, 10 Aug 2015 10:50:13 GMT

Should be as simple as:

proc template;

define statgraph barchart;

begingraph;

entrytitle "Average Mileage by Vehicle Type";

layout overlay;

barchart x=element y=Conc /

stat=sum orient=vertical ;

refline sl / lineattrs=(pattern=dash);

refline wl / lineattrs=(pattern=solid);

endlayout;

endgraph;

end;

run;

proc sgrender data=txrf_final_table template=barchart;

run;

If you need reference on anything graph orientated, I would recommend looking at this blog: http://blogs.sas.com/content/graphicallyspeaking/

It has examples of pretty much everything, examples given in both sgplot and GTL in most cases.

Re: proc gchart annotate target for each bar

Jay54 — Mon, 10 Aug 2015 13:25:44 GMT

RW9 has provided the code needed for this case using GTL. I cannot see the result since the data is not included. The REFLINE statements are SGPLOT versions and will not work in GTL. With GTL, you need:

Referenceline y=sl / lineattrs=(pattern=solid);

One reason to use GTL in this case would be the TARGET option. See documentation.

Alternatively, you can also use SGPLOT procedure to do the same. I used sashelp.cars to see some results.

Refline values can be numbers, macro variables or columns in the data.

title "Average Mileage by Vehicle Type";

proc sgplot data=sashelp.cars;

vbar type / response=mpg_city stat=mean;

refline 10 / lineattrs=(pattern=dash);

refline 20 / lineattrs=(pattern=solid);

run;

Re: proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 13:30:36 GMT

Thanks for your answers but this is not what I need.

I need to draw a small line on each bar , one SL, one WL. The SL and WL is different for each BAR! Actually it is more lixe a boxplot, but without the boxes?

Re: proc gchart annotate target for each bar

Jay54 — Mon, 10 Aug 2015 13:33:46 GMT

In that case, you need to overlay two statements, one to draw the bar, one to draw the target.

Which version of SAS are you using (with maintenance level)? Do you have SAS 9.3 or higher?

Re: proc gchart annotate target for each bar

RW9 — Mon, 10 Aug 2015 13:42:37 GMT

Just from my side here, I would do this kind of thing for normal ranges. First I would take a distinct list and in that dataset have the higher lower for each parameter as this will differ. From that dataset I then generate the code:

data refs;

param="ABC"; higher=23; lower=4; output;

param="DEF"; higher=12; lower=8; output;

run;

proc template;

...

dynamic _h _l;

...

Referenceline y=_h / lineattrs=(pattern=solid) name="UpperRange";

Referenceline y=_l / lineattrs=(pattern=solid) name="LowerRange";

...

run;

data _null_;

set refs;

call execute(cats('proc sgrender data=have (where=(param="',param,'")) template=...; dynamic _h=',put(higher,best.),' _l=',put(lower,best.),'; run;');

run;

In this way the sgrender is called once per parameter and the dynamic variable is set to the respective range.

Re: proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 13:45:16 GMT

We have SAS 9.2

For Base Product ...

Custom version information: 9.21_M3

For SAS/STAT ...

Custom version information: 9.22

For SAS/GRAPH ...

Custom version information: 9.21_M2

Re: proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 13:48:30 GMT

Yes, but the reference line can NOT be drawn over the whole graph. Only on the bar where it should be.

Re: proc gchart annotate target for each bar

Jay54 — Mon, 10 Aug 2015 13:54:34 GMT

You have less options with SAS 9.2, and may need to use GTL as suggested by RW9. I would use an overlay of bars and scatter.

To get a line over the bar, you may need some more code. Easier with SAS 9.3 or later. 🙂

proc means data=sashelp.cars;

class type;

var mpg_city mpg_highway;

output out=cars(where=(_type_ > 0))

mean (mpg_city mpg_highway)=city highway;

run;

proc template;

define statgraph bars;

begingraph;

entrytitle "Average Mileage by Vehicle Type";;

layout overlay / yaxisopts=(offsetmin=0);

barchart x=type y=city / name='a';

scatterplot x=type y=highway / name='b';

discretelegend 'a' 'b';

endlayout;

endgraph;

end;

run;

proc sgrender data=cars template=bars;

run;

Re: proc gchart annotate target for each bar

Filipvdr — Mon, 10 Aug 2015 14:15:05 GMT

thanks Sanjay, this is already more the way they want it to be. I will look further now to customize and change the icons.

Re: proc gchart annotate target for each bar

Jay54 — Mon, 10 Aug 2015 14:33:54 GMT

Time to upgrade. Anything higher than SAS 9.2 will provide you more options, including annotation.

I came into this thread a bit late because I figured GCHART with annotate would be the right solution, especially with SAS 9.2.

Why did that not work?

Re: proc gchart annotate target for each bar

Filipvdr — Wed, 12 Aug 2015 10:46:54 GMT

Hello all: i got this now:

proc template;

define statgraph barchart;

begingraph;

entrytitle "&wafersource_list";

layout overlay /

yaxisopts=(offsetmin=0

label="Conc (E10A/cm2)"

tickstyle=across);

barchart x=element y=Conc / name='a' fillattrs=(color=cxFFFF66) ;

scatterplot x=element y=WL / name='b' markerattrs=(symbol=HomeDown);

scatterplot x=element y=SL / name='c' markerattrs=(symbol=HomeDownFilled);

discretelegend 'a' 'b' 'c';

endlayout;

endgraph;

end;

run;

What i would like to now is:

1: remove the border around the graph

2: put more ticks on the y ax

any ideas?

Re: proc gchart annotate target for each bar

RW9 — Wed, 12 Aug 2015 10:52:36 GMT

Well, to remove the border it should be as straightforward as:

ods graphics / reset=all height=15cm width=19cm noborder;

For more tickaxis values:

yaxisopts=(offsetmin=0 label="Conc (E10A/cm2)" tickstyle=across tickvaluesequence=(start=0 end=100 increment=10));

^ ^ ^

Change these to your ranges. You could also put a list in there and specify exactly what ticks you want.

Re: proc gchart annotate target for each bar

Filipvdr — Wed, 12 Aug 2015 11:02:00 GMT

thanks a lot RW9. I have put my max and increment into some macro variables. works fine!

ods graphics / reset=all height=15cm width=19cm noborder;

proc template;

define statgraph barchart;

begingraph;

entrytitle "&wafersource_list";

layout overlay /

yaxisopts=(offsetmin=0

label="Conc (E10A/cm2)"

tickstyle=across

linearopts= (tickvaluesequence=(start=0 end=&max increment=&interval)));

barchart x=element y=Conc / name='a' fillattrs=(color=cxFFFF66) ;

scatterplot x=element y=WL / name='b' markerattrs=(symbol=HomeDown);

scatterplot x=element y=SL / name='c' markerattrs=(symbol=HomeDownFilled);

discretelegend 'a' 'b' 'c';

endlayout;

endgraph;

end;

run;

Re: proc gchart annotate target for each bar

GraphGuy — Mon, 21 Sep 2015 17:31:10 GMT

Here's one way to do it, using GChart & Annotate ...

data foo;
input country $ 1-10 value sl wl;
datalines;
France 12 10 30
Germany 35 20 50
Turkey 20 25 35
Greece 10 30 45
;
run;

data anno_lines; set foo;
length function color $8;
ysys='2'; hsys='3'; when='a';

function='move'; midpoint=country; xsys='2'; y=sl; output;
function='move'; x=-10; xsys='7'; output;
function='draw'; x=10*2; size=1.0; color='red'; output;

function='move'; midpoint=country; xsys='2'; y=wl; output;
function='move'; x=-10; xsys='7'; output;
function='draw'; x=10*2; size=1.0; color='green'; output;
run;

axis1 label=none value=(angle=90);
axis2 label=none order=(0 to 60 by 10);

pattern1 v=s c=cx63B8FF;

proc gchart data=foo anno=anno_lines;
vbar country / type=sum sumvar=value
maxis=axis1 raxis=axis2 noframe
width=4 space=3;
run;