topic Re: SGPANEL PANELBY modify header attributes SAS 9.3 in Graphics Programming

SGPANEL PANELBY modify header attributes SAS 9.3

data_null__ — Sun, 23 Nov 2014 18:04:08 GMT

In 9.4 I can use HEADERATTRS option but I want to change the font size using SAS 9.3 that does not support that option. Can I do the same another way?

proc sgpanel data=sashelp.class;

panelby age / layout=rowlattice rowheaderpos=right headerattrs=(size=18pt);

series x=weight y=height;

run;

Re: SGPANEL PANELBY modify header attributes SAS 9.3

Jay54 — Mon, 24 Nov 2014 00:56:55 GMT

Here is one work around. Cell headers use the GraphValueFont attribute for rendering. This is also used by things like axis tick values, and maybe other things like legend values, etc.. You can derive a font, and change this attribute in GraphFonts. Then, you can set the axis values back to the smaller font by using the ValueAttrs on the axis.

proc template;

define style Styles.Fonts;

parent = styles.listing;

class GraphFonts

"Fonts used in graph styles" /

'GraphValueFont' = ("<sans-serif>, <MTsans-serif>",12pt)

;

end;

run;

ods html style=Styles.Fonts;

proc sgpanel data=sashelp.class;

panelby sex;

vbar age;

colaxis valueattrs=(size=8);

rowaxis valueattrs=(size=8);

run;

Re: SGPANEL PANELBY modify header attributes SAS 9.3

data_null__ — Tue, 25 Nov 2014 11:56:50 GMT

Thank you. My Spaghetti Plots are beautiful.

Is the "connection" between GraphValueFont and the Cell Header documented somewhere?

Re: SGPANEL PANELBY modify header attributes SAS 9.3

Jay54 — Tue, 25 Nov 2014 14:25:12 GMT

Some of such doc is available in the "GRL Users' Guide" book in the SAS doc in the Appendix. Look under "Graph Style Elements used by ODS Graphics".

Can you share a picture of your Spaghetti plot? Just curious.