topic How to get rid of legend of reg fit plot using SAS 9.4 ODS graphics editor? in Graphics Programming

How to get rid of legend of reg fit plot using SAS 9.4 ODS graphics editor?

xinjian — Mon, 27 Oct 2014 19:42:03 GMT

Dear All,

I made a fit plot graph with attached file using SAS 9.4, the program is below:

ods listing sge = on;

procreg data=baseline2;

model ba=bs;

run;

I don't want legends especially 'observation, parameters, error DF, etc'.

I appreciate your help.

Thanks,

Xinjian

Re: How to get rid of legend of reg fit plot using SAS 9.4 ODS graphics editor?

Jay54 — Wed, 29 Oct 2014 21:33:44 GMT

There is no way to remove a Legend or the Statistics table from a graph using the ODS Graphics Editor. However, you could use the following code to get the data from proc REG and plot it using SGPLOT.

ods output fitplot=fitdata;

proc reg data=sashelp.class;

model weight=height;

run;

proc sort data=fitdata out=sorted;

by _indepvar1;

run;

ods graphics / reset width=6in height=4in imagename='ClassWeightbyHeightFitPlot';

proc sgplot data=sorted nocycleattrs noautolegend;

band x=_indepvar1 upper=uppercl lower=lowercl / nofill lineattrs=(pattern=dash);

band x=_indepvar1 upper=upperclmean lower=lowerclmean;

reg x=_indepvar1 y=predictedvalue / nomarkers;

scatter x=_indepvar1 y=depvar;

run;

For a simple fit plot, it would be even easier to just use the REG statement inside proc SGPLOT:

ods graphics / reset width=6in height=4in imagename='ClassFitPlot';

proc sgplot data=sashelp.class nocycleattrs noautolegend;

reg x=height y=weight / cli clm;

run;

Re: How to get rid of legend of reg fit plot using SAS 9.4 ODS graphics editor?

xinjian — Thu, 30 Oct 2014 01:54:07 GMT

It is good to know ods graphic editor cannot change legend. I tried your way to get job done. Thanks so much for your effort.