topic Re: special symbol in gplot labels in Graphics Programming

special symbol in gplot labels

Ken_oy — Thu, 15 Nov 2012 22:12:06 GMT

Hi everyone.

Just a quick question. How can we use label statement in gplot to put special symbols in axis label?

For example, how to put a 'um' (mu m) there? I tried to copy that 'mu' symbol from "system map" (ms windows), but it just did not work.

Any suggestion? or any other method to do so? thanks.

Re: special symbol in gplot labels

Ken_oy — Thu, 15 Nov 2012 22:29:28 GMT

I found a way to do this, by using the following code:

label=(f=arial h=3 c=black justify=c a=90 "Length (%sysfunc(byte(181),$1.)m)" )

The "%sysfunc(byte(181),$1.)" should show as the the 'mu' sign in the gplot. The number "181" came from the following unicode chart: (link)

Unicode Chart

We can see that "mu" can be located from "181" (Latin-1 Supplement chart). If we want other symbols, we can just simply replace the "181" with other numbers.

Then here comes the second question:

The method above works and only works for Latin-1 Supplement chart. How if we want to throw in other special symbols?

Re: special symbol in gplot labels

DanH_sas — Thu, 15 Nov 2012 22:30:28 GMT

For GPLOT, you can do it this way:

axis1 label=(font="Arial/unicode" "03bc"x "006d"x);

proc gplot data=sashelp.class;

plot weight*height / haxis=axis1;

run;

quit;

Assuming you have SAS 9.2 or greater, you can do this in SGPLOT using ODS escapement syntax:

proc sgplot data=sashelp.class;

xaxis label="(*ESC*){unicode mu}m";

scatter x=weight y=height;

run;

Hope this helps!

Dan

Re: special symbol in gplot labels

Ken_oy — Thu, 15 Nov 2012 22:38:57 GMT

@DanH, Thanks for the quick reply. I tried you code, the code worked. The problem is, the "mu" and the "m" overlap each other. How can I set them one after another in the label? Thanks again!

Re: special symbol in gplot labels

Ken_oy — Thu, 15 Nov 2012 22:40:09 GMT

What I tired was the GPLOT code, have not tried the Sgplot yet, but I will

Re: special symbol in gplot labels

DanH_sas — Thu, 15 Nov 2012 22:42:21 GMT

Interesting...I don't see this overlap problem in my GPLOT output. What version of SAS do you have?

Re: special symbol in gplot labels

DanH_sas — Thu, 15 Nov 2012 22:49:33 GMT

I just ran the GPLOT example in 9.2 and 9.3, and the output in neither version showed the overlap. Could you have some settings active that could affect your graph rendering? Maybe start a fresh session and see if it still happens.

Re: special symbol in gplot labels

ballardw — Thu, 15 Nov 2012 23:04:39 GMT

Maybe go more old school and avoid the unicode by using one of the SAS GREEK fonts?

Re: special symbol in gplot labels

GraphGuy — Fri, 16 Nov 2012 14:46:25 GMT

Could you show the exact axis statement you're using when you see the overlap?

Is the axis label text horizontal, or angled?

One possible work-around is to insert some extra spaces between the two characters:

axis1 label=(font="albany amt" 'Here is a mu character:'

font="albany amt/unicode" '03bc'x font="albany amt" ' ' font="albany amt/unicode" '006d'x);

proc gplot data=sashelp.class;

plot height*weight / haxis=axis1;

run;

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 14:48:14 GMT

@DanH. I had the SAS 9.2, I tried to restart my SAS, but still keep having this "overlap" style label. I thought I might mess up the goption settings, but after doing a goption reset=all, I still got the following graph.

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 14:53:25 GMT

, Thanks for the advice. I tried your code but still had the sample overlap looking result.

In my Label statement, I used:

axis2 order= 0 to 800 by 100

value=(f=arial c=black h=2.5)

label=( h=3 c=black a=90 font="Arial/unicode" "03bc"x font="albany amt" ' ' font="albany amt/unicode" '006d'x )

minor=none;

I also tested DanH's code:

axis2 order= 0 to 800 by 100

value=(f=arial c=black h=2.5)

label=( h=3 c=black a=90 font="Arial/unicode" "03bc"x "006d"x )

minor=none;

Re: special symbol in gplot labels

GraphGuy — Fri, 16 Nov 2012 14:57:57 GMT

Are you using Proc Boxplot, or Proc Gplot (or other)?

Which output are you using? (dev=png, dev=actximg, dev=javaimg, other?)

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 15:01:32 GMT

no, I used gplot + %annotate to do those boxplots. Did not use any dev options.

I think it should be my SAS version problem.

Re: special symbol in gplot labels

GraphGuy — Fri, 16 Nov 2012 15:01:48 GMT

What do you get when you run the following?...

goptions device=png;

axis1 label=(angle=90 font="albany amt" 'Here is a mu character: '

font="albany amt/unicode" '03bc'x font="albany amt" ' ' font="albany amt/unicode" '006d'x);

axis2 offset=(15,15);

symbol1 value=circle interpol=boxcti;

proc gplot data=sashelp.class;

plot height*sex / vaxis=axis1 haxis=axis2;

run;

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 15:06:08 GMT

, here it is. you can see the "mu m' is in the middle of the v-axis

Re: special symbol in gplot labels

GraphGuy — Fri, 16 Nov 2012 15:15:06 GMT

Yep - it seems that maybe you've got an older version of SAS that had some quirks with angled y-axis text labels ... several small spacing issues were fixed in both 9.2 and 9.3. I would definitely recommend upgrading to 9.3 if possible!

In the meantime, perhaps one work-around is to not rotate the y-axis label. With such a short label, it would fit just as well non-rotated (and would be easier to read non-rotated). **This is the work-around I would recommend.

Another possible work-around might be to annotate the text for the y-axis label (if you really want it rotated). In the worst-case, you could annotate each character separately, and put them anywhere you want.

Re: special symbol in gplot labels

DanH_sas — Fri, 16 Nov 2012 15:16:42 GMT

Ah, I was putting the label on the X axis instead of the Y axis, which would explain why I was not getting the overlap. Since you are running 9.2, and I know what type of plot you're generating, would this work for you?

proc sgplot data=sashelp.class;

yaxis label="This label contains a (*ESC*){unicode mu}m";

vbox height / category=age;

run;

Re: special symbol in gplot labels

GraphGuy — Fri, 16 Nov 2012 15:20:50 GMT

And, as ballardw mentioned, you could try the SAS/Graph 'greek' software font. The character won't be smooth/anti-aliased, but it's easier to get the spacing right with the software fonts:

goptions device=png;

axis1 label=(angle=90 font=swiss 'Here is a mu character: '

font=greek 'm' font=swiss ' m');

axis2 offset=(15,15);

symbol1 value=circle interpol=boxcti;

proc gplot data=sashelp.class;

plot height*sex / vaxis=axis1 haxis=axis2;

run;

All the characters in the SAS/Graph 'greek' software font can be found in a table on the following page:

http://support.sas.com/documentation/cdl/en/graphref/63022/HTML/default/viewer.htm#font-font-lists.htm

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 15:23:40 GMT

Yes, I agree. Using annotate we can do what ever we want in gplot. But the only problem is efficiency. Anyway, I am getting my 9.3 at the end of this month. I already learned about its improvement. Looking forward to having it :smileygrin:. Thanks for the advice again!

Re: special symbol in gplot labels

Ken_oy — Fri, 16 Nov 2012 15:26:04 GMT

, Yes your code worked in sgplot! thanks! The only reason that I did not use sgplot for my boxplot was that there is no "group" statement in SAS9.2. So still a SAS version problem, lol. But your code will be very useful for the future! thanks!!