topic Re: SGPLOT VBAR and a user defined format on the category variable in Graphics Programming

SGPLOT VBAR and a user defined format on the category variable

FrankPoppe — Wed, 03 Jul 2013 12:57:08 GMT

Hi,

I started to use SGPLOT (it was on my list for sometime, but now I doing work for a site with EG connected to a server that does not have SAS/Graph).

I had a simple VBAR very quickly, but am surprised that user defined formats do not seem to work when used on the variable that defines the bars.

As an example I have the following code (changed to work with a SASHELP table). I added the GPLOT and FREQ procs just to show the effect of the user defined format.

When I use the NLDATEMD format it runs as expected, grouping data per month-day combination.

When I use the DAGNUM format SGPLOT shows one bar labeled %0d, and prints a warning "The data for a BARCHARTPARM statement are not appropriate. The BARCHARTPARM statement expects summarized data. The bar chart might not be drawn correctly." But the NLDATEMD format also leads to aggregation, and this happens without problems. And my original code did have only one observation per bar (it contained data for a single month, that's why I wanted only the number of the day displayed).

We have SAS 9.3 on the server.

Or am I missing something in the documentation; or doing something silly?

proc format ; 
 picture dagnum  low-high='%0d' ( datatype=date ); 
 run ; 
data ; 
 do x = '1jun2013'd to '30jun2013'd by 5 ; 
 put x= dagnum2. ;
end ; 
run ; 

 
/*%let format = nldatemd. ;*/
%let format = dagnum. ; 
 
proc sgplot data=sashelp.stocks ( where= (stock="IBM") ) ; 
vbar date / response=open ;
format date &format ; 
run ; 
 
proc gchart data=sashelp.stocks ( where= (stock="IBM") ) ;
vbar date / discrete sumvar=open ;
format date &format ; 
run ; 
 
proc freq  data=sashelp.stocks ( where= (stock="IBM") ) ;
tables date ;
format date &format ;
run ;

Re: SGPLOT VBAR and a user defined format on the category variable

AncaTilea — Wed, 03 Jul 2013 13:03:32 GMT

Hi,

the first thing that comes to mind is that you are missing the letter 't' in the &format in this statement:

proc gchart data=sashelp.stocks ( where= (stock="IBM") ) ;

vbar date / discrete sumvar=open ;

format date &forma;

run ;

Try and see what happens now?

Re: SGPLOT VBAR and a user defined format on the category variable

FrankPoppe — Wed, 03 Jul 2013 13:05:52 GMT

Sorry, that was a typo introduced while formatting this message. I'll edit the message.

Re: SGPLOT VBAR and a user defined format on the category variable

Jay54 — Wed, 03 Jul 2013 13:18:01 GMT

There may be a bug with the java formatter for this particular format. Try this code. It formats the data on server, and then sends it to SGPLOT. The warning message is an internal issue that may be a bit confusing. We'll look into it.

proc format ;
picture dagnum low-high='%0d' ( datatype=date );
run ;

data ;
do x = '1jun2013'd to '30jun2013'd by 5 ;
put x= dagnum2. ;
end ;
run ;

data formatted;
set sashelp.stocks ( where= (stock="IBM") );
NewDate=put(date, dagnum2.);
run;

proc sgplot data=formatted ;
vbar newdate / response=open

run ;

Re: SGPLOT VBAR and a user defined format on the category variable

FrankPoppe — Wed, 03 Jul 2013 13:25:56 GMT

OK, thanks,

First massaging the data is of course an option. I tried to avoid that.

I won't even need the format then, I can just use the DAY function.

Re: SGPLOT VBAR and a user defined format on the category variable

Jay54 — Wed, 03 Jul 2013 13:30:30 GMT

It is likely a bug. Feel free to report it to Tech Support. We'll look into it.

Re: SGPLOT VBAR and a user defined format on the category variable

Jan_TSNL — Wed, 10 Jul 2013 13:11:06 GMT

Dear Frank & Sanjay,

We just made a Defect out of this.

Thanks for your input, making SAS better!

Re: SGPLOT VBAR and a user defined format on the category variable

AndyK_ — Thu, 15 Oct 2015 16:50:22 GMT

I'm still seeing this bug in 9.4. As Sanjay mentioned, a workaround is to write the variable with the user-defined format into a new variable without a user-defined format (using PUT).

In my experience this error is thrown inconsistently, requiring previously error-free code to be patched.

Re: SGPLOT VBAR and a user defined format on the category variable

Jay54 — Thu, 15 Oct 2015 17:37:58 GMT

User Defined Formats are supported in general for SGPLOT, but there is a known lack of support for some picture format features for all ODS Graphics procedures. As mentioned earlier, a workaround would be to create another variable day=put(date, dagnum.); and then plot that.

data stocks;
set sashelp.stocks ( where= (stock="IBM") );
day=put(date, dagnum.);
run;

proc sgplot data=stocks ( where= (stock="IBM") ) ;
vbar day / response=open ;
run ;

Re: SGPLOT VBAR and a user defined format on the category variable

AndyK_ — Thu, 15 Oct 2015 19:12:04 GMT

Thanks Sanjay, that's good to know. I will keep an eye out on other ODS graphics procedures. In my particular case it was a user-defined numeric format causing the issue, not a picture format.