topic Re: how to pick up more than 1 max values in Graphics Programming

how to pick up more than 1 max values

John70 — Thu, 19 Jul 2012 17:28:30 GMT

Dear All, how to pick up more than 1 max values in a column and flag them in another column? see attached code. thanks!

GraphGuy — Thu, 19 Jul 2012 18:13:53 GMT

Hmm ... not really a Graph question, but here is one way to do it...

data sample;
input id x;
datalines;
18 1
18 1
18 2
18 1
18 2
369 2
369 3
369 3
361 1
;
run;

proc sql;
create table sample as
select sample.*, max(x) as group_max
from sample
group by id;
quit; run;

data sample (drop=group_max); set sample;
if x=group_max then xmax=x;
run;

MikeZdeb — Thu, 19 Jul 2012 18:39:44 GMT

hi ... another SQL idea ...

proc sql;

create table sample as

select *,

case

when x eq max(x) then max(x)

else .

end as xmax

from sample

group by id;

quit;

Linlin — Thu, 19 Jul 2012 19:09:30 GMT

The more the merrier:

data sample;
input id x;
datalines;
18 1
18 1
18 2
18 1
18 2
369 2
369 3
369 3
361 1
;
proc sort ;
by id descending x;
run;

data want ;
retain xmax;
set sample;
by id;
xmax=ifn(first.id,x,xmax);
xmax=ifn(x=xmax,xmax,.);
proc print; run;

John70 — Thu, 19 Jul 2012 20:08:45 GMT

Thanks All !