topic Re: Multiples box plots in Graphics Programming

Multiples box plots

SASdevAnneMarie — Wed, 25 Feb 2026 08:21:30 GMT

Hello Experts,

I would like to plot multiple pairs of box plots, all next to each other, for example, 6 in one page. I’m wondering if it is possible.

Actually, I use PROC SGPLOT with pdf ods and I have one page for box plot.

Thank you for your help.

Re: Multiples box plots

Ksharp — Wed, 25 Feb 2026 09:56:33 GMT

You could combine these 6 box into one picture :

https://blogs.sas.com/content/graphicallyspeaking/2022/09/10/complex-layouts-using-the-sg-procedures/

Re: Multiples box plots

Ksharp — Wed, 25 Feb 2026 09:57:36 GMT

or using GTL language.
Check PROC TEMPLATE.

Re: Multiples box plots

BrunoMueller — Wed, 25 Feb 2026 12:36:27 GMT

How about using ODS LAYOUT, see sample below.

ods _all_ close;

ods graphics / width=80mm height=80mm outputfmt=static;
ods pdf file="c:\temp\layout_gridded.pdf";

ods layout gridded columns=2;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;

ods layout end;
ods pdf close;

Re: Multiples box plots

SASdevAnneMarie — Wed, 25 Feb 2026 12:54:29 GMT

I use startpage=no but I still have the multiple pages :

options  device=SASPRTC nodate nonumber orientation=portrait ;

ods pdf style=Sapphire startpage=no;

	proc sgplot data=bdd;
		vbox NBMEN20/datalabel=LIBGEO  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
		yaxis label="Nombre de ménages";
	run;
    proc sgplot data=bdd_
		vbox NBPERSC2/datalabel=LIBGEO  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
		yaxis label="Nombre de personnes";
	run;
  proc sgplot data=bdd;
		vbox MED0 /datalabel=LIBGEO  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
		yaxis label="Médiane";
	run;

	footnote j=left "Source de données : xxx  " ;
footnote;
ods pdf close;

Re: Multiples box plots

sbxkoenk — Wed, 25 Feb 2026 13:21:20 GMT

I would use PROC SGPANEL with a panelby statement and a vbox statement.

Sample 69825: Using the SGPANEL procedure to create panels of box plots with marker symbols

https://support.sas.com/kb/69/825.html

Ciao,

Koen

Re: Multiples box plots

Ksharp — Thu, 26 Feb 2026 06:08:12 GMT

I used BrunoMueller 's code and got this :

ods graphics / width=150px height=150px outputfmt=static;
ods pdf file="c:\temp\layout_gridded.pdf";

ods layout gridded columns=4 ;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;

ods layout end;
ods pdf close;

Re: Multiples box plots

Ksharp — Thu, 26 Feb 2026 06:04:09 GMT

And I used GTL and got this:


proc template;
define statgraph y2axis;
begingraph /border=off;
layout lattice /rows=1 columns=4 ; 

layout overlay;
boxplot y=weight;
endlayout;

layout overlay;
boxplot y=height;
endlayout;

layout overlay;
boxplot y=Diastolic;
endlayout;


layout overlay  ;
boxplot y=Systolic;
endlayout;


endlayout;
endgraph;
end;
run;

ods pdf file="c:\temp\layout_gridded.pdf";
proc sgrender data=sashelp.heart(obs=1000) template=y2axis;
run;
ods pdf close;

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 08:15:29 GMT

You are not using ODS LAYOUT and you do not specify the size of the image to create, so I guess that is why you do not have them on the same page.

Re: Multiples box plots

SASdevAnneMarie — Thu, 26 Feb 2026 10:34:07 GMT

Thank you, unfortunately this code does not work when I add the statistics :


ods graphics / width=150px height=150px outputfmt=static;
ods pdf file="xxx\layout_gridded.pdf";
options  device=SASPRTC nodate nonumber  ;
ods layout gridded columns=4 ;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice/datalabel=model displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower/datalabel=model  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city/datalabel=model   displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway/datalabel=model   displaystats=(n mean median max datamax min datamin  iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1;
run;

ods layout end;
ods pdf close;

Re: Multiples box plots

SASdevAnneMarie — Thu, 26 Feb 2026 10:36:54 GMT

Thank you, Bruno!
Unfortunately, when I add the statistics : datalabel=model displaystats=(n mean median max datamax min datamin iqr range std q1 q3) datalabelattrs=(size=10pt Family="Arial" color=blue Style=Normal Weight=Normal) boxwidth=1 the box plots become small.

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 13:26:59 GMT

Since you output to a PDF, you can set some options like papersize and margins. You could use a A3 papersize, so there is more space for the graph, but still print it as A4. I would set the height and width using mm, as you can measure on the paper with a ruler. ODS LAYOUT has support for COLUMN_GUTTER=dimension and ROW_GUTTER=dimension

Here is a sample to test things out. I used macros for some of the options to make it easier to change

ods _all_ close;
options
  papersize="A3"
  topmargin=1cm
  bottommargin=1cm
  leftmargin=1cm
  rightmargin=1cm
  orientation=landscape
  nodate nonumber;
;
ods graphics / reset=all width=90mm height=135mm outputfmt=png;
ods pdf file="%sysfunc(pathname(work))/layout_gridded.pdf";
ods layout gridded columns=4 column_gutter=0;

%macro dataLabel;
  datalabel=model 
    labelfar
%mend;

%macro displayStats;
  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3)
%mend;

%macro datalabelAttrs;
  datalabelattrs=(size=6pt color=blue Style=Normal Weight=Normal) boxwidth=1
%mend;

ods region;

  proc sgplot data=sashelp.cars;
    vbox invoice /
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox horsepower/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox mpg_city/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox mpg_highway/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods layout end;
ods pdf close;

The PDF produced is attached.

Re: Multiples box plots

SASdevAnneMarie — Thu, 26 Feb 2026 14:48:13 GMT

Thank you, Bruno!
How to define 2 rows please if I want to have 8 box-plots?

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 15:02:11 GMT

As long as two rows of images will fit on the page you just continue with

ods region;
proc sgplot ...;

for the next 4 plots.

Re: Multiples box plots

SASdevAnneMarie — Thu, 26 Feb 2026 16:30:54 GMT

When I add a footnote, I get the footnote for both the graphics and at the bottom of the page. How can I have the footnote only at the bottom of the page?

Re: Multiples box plots

Ksharp — Fri, 27 Feb 2026 06:43:13 GMT

You could use NOGFOOTNOTE to get this.

ods pdf file="c:\temp\layout_gridded.pdf" nogfootnote;

Re: Multiples box plots

SASdevAnneMarie — Fri, 27 Feb 2026 08:49:17 GMT

Thank you, but when I add nogfootnote I do not have the footnote.

Re: Multiples box plots

SASdevAnneMarie — Fri, 27 Feb 2026 11:11:13 GMT

Thank you, that works.

Re: Multiples box plots

Ksharp — Fri, 27 Feb 2026 09:38:08 GMT

I don't think so.

ods graphics / width=150px height=400px outputfmt=static;
options orientation=landscape;
ods pdf file="c:\temp\layout_gridded.pdf" nogfootnote;
footnote 'xxxxxxxxx';
ods layout gridded columns=4 ;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;

ods layout end;
ods pdf close;

Re: Multiples box plots

Ksharp — Fri, 27 Feb 2026 09:41:41 GMT

Here you go:

ods graphics / width=150px height=400px outputfmt=static;
options orientation=portrait;
ods pdf file="c:\temp\layout_gridded.pdf" nogfootnote;
footnote 'xxxxxxxxx';
ods layout gridded columns=4 ;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;





ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;

ods layout end;
ods pdf close;