topic Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement in Graphics Programming

SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

MingC — Mon, 08 Sep 2025 09:40:39 GMT

When I'm creating a x-axis table using GTL axistable statement in a layout overlay statement, I find the x-axis table label (see below part marked as yellow) could not align, I tried to use labelhalign=left or labeljustify=left, but in vain. I also tried tickvaluehalign=left, but doesn't work.Any help are appreciated.

proc template;
    define statgraph lineplot;
    begingraph/attrpriority=none datacontrastcolors=(red blue orange);
 
    entrytitle halign=left "&cat."/  textattrs=(size=8) ;
                          
     layout lattice / columns=1 rows=3 rowweights=(0.87 0.03 0.1) columndatarange=union rowdatarange=union;
  
        *cell with line plot;
        layout overlay / yaxisopts=(type=log logopts=(base=2 tickintervalstyle=logexpand
                           tickvaluelist=(32 64 256 1024 4096 16384 65536 262144 1048576 /*4194304 16777216*/) tickvaluepriority=true )
                           label="Median titre" labelattrs=(size=9pt) tickvalueattrs=(size=8pt))
                        xaxisopts=(display=(TICKS TICKVALUES LABEL line) label="Timepoint" labelattrs=(size=9pt) tickvalueattrs=(size=8pt));
 
           seriesplot  x=avisit_wk y=_median / group = AVALCAT display=all groupdisplay = cluster clusterwidth = 0.2 name = 'series';                       
           scatterplot x=avisit_wk y=_median /yerrorlower=_q1 yerrorupper=_q3
             ERRORBARATTRS=(pattern=dot) group = AVALCAT groupdisplay = cluster clusterwidth = 0.2 ;                           
                                                                       
           discretelegend "series" / title='' titleattrs=(size=9pt) valueattrs=(size=9pt)
                                  displayclipped = true across=4 border=false location=outside halign=center valign=bottom;
        endlayout;
               
       *cell with axistable values (n);
         layout overlay ;
            entry halign=left "n"/textattrs=(size=9pt);
         endlayout;
                     
        layout overlay / walldisplay=none halign=left xaxisopts=(tickvalueattrs=(size=8pt) display=none)
                                   /*yaxisopts=(display=(tickvalues ) tickvaluehalign=left)*/;
           axistable x=avisit_wk value=n /display=(label) /*labelhalign=left labeljustify=left*/ valueattrs=(size=9pt) labelattrs=(size=9pt) 
              class=AVALCAT colorgroup=AVALCAT;
        endlayout;      
                                   
    endlayout;
    endgraph;
  end;
run;
ods graphics on/noborder;  
ods noptitle;

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

FreelanceReinh — Mon, 08 Sep 2025 11:53:33 GMT

Hello @MingC and welcome to the SAS Support Communities!

@MingC wrote:

(...) I tried to use labelhalign=left or labeljustify=left, but in vain.

Sadly, the documentation of both these options says:

Restriction This option applies only to Y-axis tables.

Restriction	This option applies only to Y-axis tables.

@MingC wrote:

I also tried tickvaluehalign=left, but doesn't work.

I think this option does not apply to the axis table.

Unless someone else has a better idea, here is a workaround: Use a non-proportional (a.k.a. fixed-width) font for the labels to be left-aligned and pad the shorter labels with trailing non-breaking spaces so that they match the length of the longest label.

Example:

data have;
set sashelp.prdsale;
if division=:'E' then division='EDU';
run;

Using the PROC TEMPLATE example code from the AXISTABLE documentation, the x-axis table obtained with

proc sgrender data=have template=axistable;
run;

looks like this:

Default alignment

After inserting the below LABELATTRS= option into the AXISTABLE statement of the PROC TEMPLATE code

...
headerlabelattrs=GraphLabelText
labelattrs=(family='Lucida Console' size=11pt)
valueattrs=(size=9pt weight=bold)
...

and modifying the short "EDU" value,

data want;
set have;
if division='EDU' then division='EDU'||'A0A0A0A0A0'x;
run;

proc sgrender data=want template=axistable;
run;

left-alignment is achieved:

Left-aligned

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

MingC — Tue, 09 Sep 2025 02:24:18 GMT

@FreelanceReinh , thank you very much for your quick and detailed response. I was wondering if I there is a proc template options could fix the alignment, which bothered me in the past couple of weeks. After I tried your idea to add 'A0A0A0A0A0'x to the end of shorter label value, I can left-align the label now. I'll accept your idea as solution if no better idea appears in one month.

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

Jay54 — Tue, 09 Sep 2025 11:09:00 GMT

Try

VALUEJUSTIFY=AUTO | LEFT | CENTER | RIGHT

specifies the justification of the values in the axis table relative to the axis-table width.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/grstatgraph/p0v5nj3waz75w4n1s2y70echq6im.htm

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

FreelanceReinh — Tue, 09 Sep 2025 11:34:38 GMT

@MingC wrote:

@FreelanceReinh , thank you very much for your quick and detailed response. I was wondering if I there is a proc template options could fix the alignment, which bothered me in the past couple of weeks. After I tried your idea to add 'A0A0A0A0A0'x to the end of shorter label value, I can left-align the label now.

You're welcome. There doesn't seem to be a PROC TEMPLATE option to control that alignment. Glad to hear that the 'A0'x trick worked for you. (The minor imperfection in the alignment shown in your screenshot is due to the proportional font you are using.)

Another approach would be SG annotation. Continuing the example from the previous post:

%sganno;

data anno;
%sgtext(reset=all, id="xtlabel", label="EDU", textcolor="GraphData1:contrastcolor", textsize=9, textweight="bold",
        x1=0, x1space="layoutpixel", y1=69, y1space="layoutpixel", anchor="left");
%sgtext(label="CONSUMER", textcolor="GraphData2:contrastcolor", width=90, y1=55);
run;

proc template;
  define statgraph axistable;
    begingraph; 
      entrytitle "Average Product Sales By Division and Country";
      layout overlay / cycleattrs=true pad=(left=18px) 
        yaxisopts=(offsetmax=0.15 label="Sales By Country"); 
        innermargin / align=bottom opaque=true backgroundcolor=cxf5f5f5;
          axistable x=product value=actual / 
            name="division" stat=mean display=(values)
            headerlabel="Sales By Division"
            headerlabelattrs=GraphLabelText
            valueattrs=(size=9pt weight=bold)
            colorgroup=division class=division;
        endinnermargin;
        barchart category=product y=actual / name="country" 
          barlabel=true barlabelformat=dollar5.0
          stat=mean group=country groupdisplay=cluster;
        discretelegend "country" / title="Country:" location=inside
          valign=top;
        annotate / ID="xtlabel"; 
      endlayout; 
   endgraph;
 end;
run;

proc sgrender data=have template=axistable sganno=anno;
run;

The display=(values) option in the AXISTABLE statement suppresses the original labels, which are then replaced by the labels (here: hard-coded) in the annotation dataset ANNO. The new pad= option of the LAYOUT statement provides the space on the left needed for those labels. Their vertical positioning (i.e., determining the y1 coordinates) is cumbersome.

Result:

Using SG annotation

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

MingC — Wed, 10 Sep 2025 02:15:11 GMT

@Jay54 thank you for your response. But I don't think VALUEJUSTIFY works for x-axis table, because I checked your link and found it only works for y-axis tables.

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

MingC — Wed, 10 Sep 2025 02:56:42 GMT

@FreelanceReinh, Thank you for sharing another approach for SG annotation, I have little knowledge about SG annotation and never use it, but I’ll try to self-learn it.

For your first approach, yes, you have very smart eyes which found the minor imperfection in the alignment in my screenshot. I can only use the “Courier” font due to project restriction. I tried the font “Lucida Console” mentioned in your first approach, the labels can exactly left-aligned. It seems each 'A0' is for one blank space when the font is “Lucida Console”. But it seems each 'A0' is less that one blank space when using “Courier” font, I don’t know the logic behind, that’s why there is minor imperfection in my alignment.

It could be great if you can share more knowledge about proportional font, and the logic behind 'A0' for blank space. Thank you in advance.

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

FreelanceReinh — Wed, 10 Sep 2025 10:22:25 GMT

Courier is a proportional font, i.e., narrow characters like "i" occupy less space than wide characters like "m." This variability makes it virtually impossible to achieve perfect alignment by using space characters such as '20'x or 'A0'x because the exact amount of horizontal space required is most likely not an integer multiple of the width of a space character.

This problem does not occur with non-proportional fonts (where all characters have the same width) such as Courier New, Cumberland AMT or Lucida Console. I had suggested the latter because, like Courier, it is essentially a sans-serif font. See the example text below (created by TEXT statements of PROC SGPLOT) where the digit strings help counting characters.

One proportional and three fixed-width fonts.

Re: SAS GTL: How to left-align x-axis table labels created by GTL axistable statement

MingC — Thu, 11 Sep 2025 01:29:44 GMT

@FreelanceReinh, thank you for the detailed response. I love your examples, they are quite straight-forward for me, I think I know a little for the non-proportional font now.