topic Re: Cleaning up a 3D chart in Graphics Programming

Cleaning up a 3D chart

Mscarboncopy — Tue, 22 Apr 2025 12:11:10 GMT

Hello,

I am trying to generate a 3D chart for percent and need some help to finalize it.

I have tried several things and am not able to remove the extra points in the axis1.

I would also like to:

Add the percent inside each bar values are 50/ 18/32

datalines;

ID	Greetings
1	1
2	1
3	1
4	1
5	1
6	1
7	1
8	1
9	1
10	1
11	1
12	2
13	2
14	2
15	3
16	3
17	3
18	3
19	3
20	3
21	3
22	.
23	.
24	.
25	2

;

I am using this code to generate a percent graph and wanted it to be a 3D graph.

Proc format;

Value Gre

1 = 'Hello'

2 = 'Hi'

3 = 'Dear';

run;

Data want;

Set have;

Format Greetings Gre. ;

run;

proc Gchart Data=have;

vbar3d Greetings / TYPE=PERCENT;

axis1 order=(1 2 3); *not sure why this does not work;

run;

Thank you so much!

Re: Cleaning up a 3D chart

PaigeMiller — Tue, 22 Apr 2025 12:18:36 GMT

I think the FREQ option in PROC GCHART VBAR3D statement will work.

Generally speaking, 3D charts are a misleading way to display data. See https://medium.com/@purohitpraveen/data-vizualization-why-3d-charts-are-a-terrible-idea-32657fbb928e, You might want to consider the regular old 2D VBAR charts.

Re: Cleaning up a 3D chart

ballardw — Wed, 23 Apr 2025 07:05:28 GMT

Try adding MAJOR=3 to the Axis definition. That forces the appearance of exactly 3 major tick marks. Order affects that the order values are displayed. Major affects the number of displayed tick marks (or Minor the the number of minor ticks between each pair of Major ticks).

Better for many reasons would be to switch to Proc SGPLOT unless you are stuck with a version of SAS 8 or earlier.

Re: Cleaning up a 3D chart

Ksharp — Wed, 23 Apr 2025 08:04:14 GMT

Calling @GraphGuy (a.k.a Robert.Allision ) ,since you are asking some special feature with 3D chart.

Or you could try PROC SGPLOT + GTL Annotation Facility (sganno= option) to get this 3D chart, but that need to write many code to finish it.

P.S. Why not use PROC SGPLOT + VBAR to simplify this question as Paige and ballardw pointed out ?

Re: Cleaning up a 3D chart

DanH_sas — Wed, 23 Apr 2025 13:29:06 GMT

For this case, can you use the DISCRETE option on VBAR3D?

Re: Cleaning up a 3D chart

DanH_sas — Wed, 23 Apr 2025 13:50:54 GMT

Also, if you interested in a 3D-like look with 2D readability, you could try something like this:

data test;
input value;
cards;
1
1
1
1
2
2
3
3
3
3
3
3
;
run;

proc sgplot data=test;
vbar value / stat=percent dataskin=pressed;
run;

Re: Cleaning up a 3D chart

Mscarboncopy — Wed, 23 Apr 2025 14:05:26 GMT

Thanks. The link did not work.

Re: Cleaning up a 3D chart

Mscarboncopy — Wed, 23 Apr 2025 14:07:43 GMT

Thank you! It was requested that I create a 3D chart like the one I am showing. I had originally created one with PROC SGPLOT + VBAR as everyone suggested (and it would be my preference) but the graph was seen as too plain.

Re: Cleaning up a 3D chart

Mscarboncopy — Wed, 23 Apr 2025 14:09:42 GMT

Thank you @DanH_sas This is great.

Is there any way I can add the percentage value to the top of each bar?

Re: Cleaning up a 3D chart

PaigeMiller — Wed, 23 Apr 2025 14:18:42 GMT

@Mscarboncopy wrote:

Thank you! It was requested that I create a 3D chart like the one I am showing. I had originally created one with PROC SGPLOT + VBAR as everyone suggested (and it would be my preference) but the graph was seen as too plain.

You should point out that 2D charts are more readable and less likely to produce confusion on the part of the person who is viewing the chart; compared to a 3D chart. The correct link is https://medium.com/@purohitpraveen/data-vizualization-why-3d-charts-are-a-terrible-idea-32657fbb928e

Re: Cleaning up a 3D chart

DanH_sas — Wed, 23 Apr 2025 14:13:38 GMT

Add the DATALABEL option to the VBAR statement. You can also use the FILLATTR=(color=<some color>) if you want to change the color.

Re: Cleaning up a 3D chart

Mscarboncopy — Wed, 23 Apr 2025 17:00:55 GMT

@DanH_sasPerfect. Last question. Is there a way to round up the percentage? Right now I have 18.18% and 31.8% for 2 of the value points. I would like to have them display 18% and 32%. Thank you again!

Re: Cleaning up a 3D chart

Mscarboncopy — Wed, 23 Apr 2025 17:05:52 GMT

I was able to use this and it worked to remove those extra marks. But now I am considering not doing a 3D chart 🙂 In any case, great learning experience.

axis logbase=2 logstyle=expand
order=(1,2,3);

Re: Cleaning up a 3D chart

DanH_sas — Wed, 23 Apr 2025 17:08:15 GMT

On the SGPLOT statement, set PCTNDEC=0.

Re: Cleaning up a 3D chart

PaigeMiller — Wed, 23 Apr 2025 19:28:37 GMT

At the risk of offending people, I will state my opinion that the gray gradients in the 2D plot above convey no information in displaying this data, and so it meets the definition of "chartjunk". In fact, at that Wikipedia link there is a similar plot where color gradients are inserted into a map of North Macedonia, which serve no useful purpose, similar to the gray gradients in the 2D bar chart above.

Re: Cleaning up a 3D chart

Mscarboncopy — Thu, 24 Apr 2025 18:40:24 GMT

@DanH_sas Is there a similar function to round up percentage for

proc Gchart Data want;

vbar3d var/ TYPE=Percent

I've read so much and I can't find a way to be able to round the percentage in this case. I learned how to do everything else I wanted like change the points in the axis, color, width of the bars, add the percent value to the bars. But I can't find a way to round the percentage in this case.

Re: Cleaning up a 3D chart

DanH_sas — Thu, 24 Apr 2025 20:37:28 GMT

You can do it using the STATFMT option on the VAR3D statement.

Re: Cleaning up a 3D chart

Mscarboncopy — Thu, 24 Apr 2025 21:44:38 GMT

Thank you! I tried that and it did not work but I might be doing something wrong.

I also tried to use format percent8.0 to get rid of the decimals (another option)... but I do not have a Percent variable, I am creating that variable in the graph and I tried several places on my code but it won't let me format the var Percent that is being created for the graph as I showed in my original post.

This is my entire code

ODS GRAPHICS ON / RESET IMAGENAME="Fig1" IMAGEFMT=png ANTIALIASMAX=10000;

GOPTIONS RESET=ALL BORDER CBACK=WHITE HTITLE=12PT HTEXT=25PT ftext='Bold';

OPTIONS CLEANUP;

proc Gchart Data=have

vbar3d Greetings /TYPE=PERCENT

annotate=have

inside=PERCENT

patternid=midpoint

width=20

space=5

maxis=axis1

raxis=axis2

gaxis=axis3;

coutline=black;

axis logbase=2 logstyle=expand

order=(1,2,3);

axis2 label=(angle=90 'Percent');

run;

quit;

ODS GRAPHICS OFF;

run;

Re: Cleaning up a 3D chart

GraphGuy — Mon, 29 Sep 2025 13:06:15 GMT

 data have;
input ID Greetings;
datalines;
1 1
2 1 
3 1 
4 1
5 1
6 1
7 1
8 1
9 1
10 1
11 1
12 2
13 2
14 2
15 3
16 3
17 3
18 3
19 3
20 3
21 3
22 .
23 .
24 .
25 2
;
 
Proc format;
Value Gre
1 = 'Hello'
2 = 'Hi'
3 = 'Dear'
;

axis1 label=none minor=none order=(0 to 60 by 20) offset=(0,0);

axis2 label=('Type of Greeting') offset=(9,9);

pattern1 color=cyan;

title1 h=6pct font='albany amt/bold'  "Customized 3d Chart";

proc Gchart Data=have;
Format Greetings Gre. ;
vbar3d Greetings / 
 discrete space=7pct width=5pct
 raxis=axis1 autoref cref=gray33 lref=33 
 maxis=axis2
 type=percent
 outside=percent statfmt=comma5.0
 ;