topic Re: box not plotting with 2 y axes in Graphics Programming

box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 17:37:12 GMT

hi, Im looking for box plot for 3 group variables one with respect to the right handside y axis and other two to the left y axis.My code below doent give any error, but is not giivng any boxes. It creates a graphic area with default legends but not he boxes. what could be the issue/ can anyone help? Thanks

/*** read in adis and adlb data and combining ***/

proc sort data=analysis.adis(where=( paramcd in ('SAAVTSI') and avisitn>=0 and AVAL ne . )) out=adis(keep= usubjid subjid studyid paramcd param avisit avisitn aval ady rename=(aval=SAAVTSI ady=isdy));
by studyid usubjid subjid avisitn ;
run;

proc sort data=analysis.adlb(where=( paramcd in ('ALTSI' 'ASTSI') and avisitn>=0 and aval ne . )) out=adlb(keep= usubjid subjid studyid avisit avisitn paramcd param anrhi aval ady rename=(ady=lbdy aval=lbaval));
by studyid usubjid subjid avisitn ;
run;

data ip;
set adis(in=a) adlb(in=b);
if lbaval ne . then do;aval1=lbaval/anrhi;end;
else do;aval2=SAAVTSI;end;

if avisitn=0 then visx=0;
else visx=input(scan(avisit,2,''),best.);
/** jitter applies to ALT ***/
if paramcd='ALTSI' then vis=visx-0.15;
/** jitter applies to AST ***/
if paramcd='ASTSI' then vis=visx+0.15;
/** jitter applies to AAV9 ***/
if paramcd='SAAVTSI' then vis=visx+0.05;

param2=param;
param1=param;

/*if paramcd='SAAVTSI' then do;param1=param;param='z';end;
else do;param1="x";end;*/
run;

/*height=8cm width=22.0cm*/

ods graphics on / reset=all height=9.5cm width=21.0cm border=off outputfmt=png;

proc sort data=ip;by paramcd avisitn vis;run;

proc sgplot data=ip dattrmap=myattr;

vbox aval1 / category=vis group=param1 nomean nooutliers whiskerpct=25 connect=median lineattrs=( pattern=1) attrid=param1;
vbox aval2 / category=vis group=param2 y2axis nomean whiskerpct=25 connect=median ;

yaxis label='AAA value' values=(0 to 3 by 0.5) valueattrs=(size=8);
y2axis label='ZZZ titer' TYPE=LOG LOGBASE=2 ;*valueattrs=(size=8) values=(&y2vals. ) valuesformat=best. valuesdisplay=(&y2disp. );
xaxis label='Analysis visit' values=(0,1,2,3,4,6,8,10,12,16,20,24,28,32,36,40,44,48,52 ) valuesdisplay=('Baseline' 'Week 1' 'Week 2' 'Week 3' 'Week 4' 'Week 6' 'Week 8' 'Week 10' 'Week 12' 'Week 16' 'Week 20' 'Week 24' 'Week 28' 'Week 32' 'Week 36' 'Week 40' 'Week 44' 'Week 48' 'Week 52' ) fitpolicy=rotate valuesrotate=diagonal valueattrs=(size=8);

run;

ods graphics off;

Re: box not plotting with 2 y axes

DanH_sas — Mon, 10 Feb 2025 17:44:04 GMT

I noticed the LOG axis request. Are all of the values of "aval2" greater than zero?

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 17:45:12 GMT

Yes

Re: box not plotting with 2 y axes

DanH_sas — Mon, 10 Feb 2025 17:48:25 GMT

Are the axes showing values? It might be helpfully to see a image of your output.

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 17:58:30 GMT

yes. all tick marks, axes label, legends are there.

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 17:59:16 GMT

Re: box not plotting with 2 y axes

quickbluefish — Mon, 10 Feb 2025 18:21:06 GMT

Are there warnings in your log associated with the SGPLOT step?

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 18:22:03 GMT

no warnings

Re: box not plotting with 2 y axes

quickbluefish — Mon, 10 Feb 2025 18:32:37 GMT

And if you run PROC MEANS on 'aval1' and 'aval2', do the distributions match those shown on your two y-axes pretty closely?
proc means data=ip min p1 mean p99 max;
var aval1 aval2;
run;

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 18:34:45 GMT

indeed i have a line plot with the same data and have given the axes values as per that. but even if I leave the axes values with the default, i dont get the boxes !

Re: box not plotting with 2 y axes

quickbluefish — Mon, 10 Feb 2025 18:40:15 GMT

OK, and you also tried it using PARAM as the GROUP variable for both VBOX statements (rather than param1 / param2)?

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 18:43:45 GMT

yes . already tried

Re: box not plotting with 2 y axes

DanH_sas — Mon, 10 Feb 2025 18:44:39 GMT

What version of SAS are you using?

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 18:47:25 GMT

9.4 M7

Re: box not plotting with 2 y axes

DanH_sas — Mon, 10 Feb 2025 18:57:20 GMT

I made up this little test at 9.4.m7 and it seems to work. Can you try it and see if it works for you?

proc sgplot data=sashelp.heart;
vbox cholesterol / category=ageatstart group=weight_status;
vbox cholesterol / category=ageatstart group=weight_status y2axis;
y2axis type=log logbase=2;
run;

Re: box not plotting with 2 y axes

quickbluefish — Mon, 10 Feb 2025 18:57:52 GMT

Only other thing I can think of is that the 'jitter' you're applying is causing some sort of issue. If you remove the jitter, do you get the same problem? When I test this on fake data, I get warnings in the log saying that not all boxes were drawn if I either apply jitter OR if I specify 2 separate y-axes. I suspect SGPLOT might not be capable of this particular combination of things.

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 19:04:23 GMT

yes , this works. but wonder why my code which is on the similar lines doesnt work

Re: box not plotting with 2 y axes

Quentin — Mon, 10 Feb 2025 19:05:14 GMT

If you comment out the xaxis statement, do you get boxes?

If you comment out yaxis statement?

I wonder if the values you entered on the xaxis statement are not the actual values in your dataset. Or if your values are outside the yaxis.

One thing I don't like about SGPLOT vs the much older traditional GPLOT is that SGPLOT does not throw a NOTE when you have data outside of your axes. It's possible all your data is outside the axes.

You didn't show your MYATTR dataset. Could it be everything is set to transparent?

I would suggest start with a working plot that is simple, maybe:

proc sgplot data=ip ;
  vbox aval1 / category=vis group=param1 nomean nooutliers whiskerpct=25 
  connect=median lineattrs=( pattern=1) attrid=param1;
run;

And then add back more of your real code incrementally, until the boxes disappear.

Re: box not plotting with 2 y axes

Manj — Mon, 10 Feb 2025 19:11:19 GMT

Looks like the jitter created the issue. Thank you so much for pointing this.

Re: box not plotting with 2 y axes

Quentin — Mon, 10 Feb 2025 19:11:57 GMT

In the DATA step you manually introduced jitter in the values of VIS.

In the XAXIS statement you specified the values to be plotted:

values=(0,1,2,3,4,6,8,10,12,16,20,24,28,32,36,40,44,48,52 )

My guess is after you jitter the data, those values don't appear in your data.