Using styleattrs to assign multiple patterns

xxformat_com — Sat, 13 Jul 2024 10:58:38 GMT

Hi,

I came across a really strange behaviour yesterday. I've found a solution for my specific case but I've created an example for you.

fillpattern is not supported with dattrmap as mentionned by Dan

https://communities.sas.com/t5/Graphics-Programming/Proc-sgplot-dattrmap/m-p/563684

Some templates like journal2 and journal3 use pattern attribute. I haven't further investigate this approach. Feel free to add the solution with proc template if you know it.

Right now I've tried to use styleattrs statement.

For todays message I've searched and there you have the following exemple: https://communities.sas.com/t5/Graphics-Programming/SGPLOT-Vbar-graph-Data-with-Different-color-and-Pattern/m-p/826032

But my problem is as follow: As soon as I add a second background color with datacolors=, only the first pattern is applied.

proc sort data=sashelp.class
          out=class;
    by age sex;
run;    


proc sgplot data=class;
    vbarbasic age / response=height 
                    stat=mean 
                    group=sex 
                    groupdisplay=cluster
                    fillpattern;
    
    	styleattrs datafillpatterns  =(r1 l1)
	               datacontrastcolors=(red blue) 
	               datacolors        =(yellow pink);
run;

The workaround I used is to plot twice the graph: once with just the background and once with the pattern combined with the nofill option.

But my first thought here is that it is a bug. How about you?

Re: Using styleattrs to assign multiple patterns

Ksharp — Sun, 14 Jul 2024 02:21:04 GMT

You need a special option ATTRPRIORITY=NONE to make it happen.

proc sort data=sashelp.class
          out=class;
    by age sex;
run;    

ods graphics/attrpriority=none;
proc sgplot data=class;
    vbarbasic age / response=height 
                    stat=mean 
                    group=sex 
                    groupdisplay=cluster
                    fillpattern;
    
    	styleattrs datafillpatterns  =(r1 l1)
	               datacontrastcolors=(red blue) 
	               datacolors        =(yellow pink);
run;

Re: Using styleattrs to assign multiple patterns

xxformat_com — Sun, 14 Jul 2024 06:19:53 GMT

Thank you.

topic Using styleattrs to assign multiple patterns in Graphics Programming

Using styleattrs to assign multiple patterns

Re: Using styleattrs to assign multiple patterns

Re: Using styleattrs to assign multiple patterns