topic Re: RESULTS Tab and User Specific Style Template in Graphics Programming

RESULTS Tab and User Specific Style Template

xxformat_com — Sat, 29 Jun 2024 12:53:49 GMT

The following program generates a .JPG image of the graph with new bar fill colors defined in xxgraph style template?

What should be added in order to also see the changes in the RESULTS tab of SAS Studio ?

proc template;
    define style styles.xxgraph;
    parent = styles.htmlblue;
        class GraphColors / 'gdata1' = CX00B0F0 'gdata2' = CXFF33CC;
    end;
run;

ods listing gpath= "&xxproject./graph008/graphs" style=xxgraph; 
ods graphics / imagename='test' imagefmt=JPG;

proc sgplot data=sashelp.class;
    vbarbasic name / response=height group=sex;
run;

ods graphics / reset=all;

Re: RESULTS Tab and User Specific Style Template

Tom — Sun, 30 Jun 2024 00:06:53 GMT

Try changing the style of the ODS destination that SAS/Studio is using.

You can check what destinations are active by looking at SASHELP.VDEST. When I check it looks like SAS/Studio is using HTML5(WEB) as the destination name.

proc template;
    define style styles.xxgraph;
    parent = styles.htmlblue;
        class GraphColors / 'gdata1' = CX00B0F0 'gdata2' = CXFF33CC;
    end;
run;

ods HTML5(WEB) style=xxgraph;

proc sgplot data=sashelp.class ;
  title1 'XXGRAPH style';
  vbarbasic name / response=height group=sex;
run;

Result

Re: RESULTS Tab and User Specific Style Template

xxformat_com — Mon, 01 Jul 2024 16:28:40 GMT

Thank you for the name of the destination. That's what I could not find.